VBA to rename a folder (not file)

[AndrewKent]

Hi all,

I have a folder with multiple sub folders that are all "# Jan", "# Feb" ect. and rather than change these manually I am looking to write a VBA script that will loop through each sub folder and rename them to "01 Jan", "02 Feb" ect.

Any advice?

Andy

 

[gallen]

This is the code to rename. Are you Ok with the loop code?

Sub RenameFolder()

Dim sOld As String, sNew As String


    'change values as required
    sOld = "C:\Test"
    sNew = "C:\TestNew"
    
    'change name
    Name sOld As sNew
    
End Sub

 

[gallen]

After re-reading, it wasn't as simple as I thought:

This will do as you ask, replacing the "#" with the month number of the 3 chr short month name

Change the InitialPath variable as required

Sub RenameSubfolders()


Dim FileSystem As Object, Folder As Object, SubFolder As Object
Dim InitialPath As String
Dim sOld As String, sNew As String


    InitialPath = "C:\Test\Test2\"
    
    Set FileSystem = CreateObject("Scripting.filesystemobject")
    Set Folder = FileSystem.GetFolder(InitialPath)
    
    For Each SubFolder In Folder.subfolders
        sOld = SubFolder.Name
        If InStr(1, sOld, "#") > 0 Then
            sNew = Replace(sOld, "#", Format(Month("01/" & Right(sOld, 3)), "00"))
            Name InitialPath & sOld As InitialPath & sNew
        End If
    Next SubFolder


End Sub

 

[AndrewKent]

That's great! thanks for your support!