vba to offset an activecell based on cell value

[Nurzhan]

Hallo,
There's a range which filled with corresponding letters, each letter meaning in which direction the offset should take place. for example.
E4 = R
F4 = D
F5 = L
E5 to E8 = D
E9 = R
F9 to F7 = U
F6 = R
G6 = R

R = move right
D = move down
L = move left
U = move up

Basically it's a path that should lead to cell H6. And it strictly should follow the root of cells shown above.

 

[Trevor_S]

Try:

Do
  If ActiveCell.Value ="U" Then
    ActiveCell.Offset(-1,0).Activate
  Else
    If ActiveCell.Value ="D" Then
      ActiveCell.Offset(1,0).Activate
    Else
      If ActiveCell.Value ="L" Then
        ActiveCell.Offset(0,-1).Activate
      Else
        If ActiveCell.Value ="R" Then
          ActiveCell.Offset(0,1).Activate
        Else
          Exit Do
        End If
      End If
    End If
  End If
Loop

It should move the active cell until it is no longer one of those four values.

 

[Nurzhan]

Thanks Trevor_S! Great. I'm not experienced in VBA yet but these codes help me to master it.

 

[footoo]

Thanks Trevor_S! Great. I'm not experienced in VBA yet but these codes help me to master it.

Why do you need to do this ?

Here's another way :

Do
Select Case ActiveCell
    Case "R": ActiveCell(1, 2).Select
    Case "D": ActiveCell(2).Select
    Case "L": ActiveCell(1, 0).Select
    Case "U": ActiveCell(0).Select
    Case Else: Exit Do
End Select
Loop

 

[Nurzhan]

Thanks footoo! This is even simpler.

 

[Nurzhan]

Dear footoo ! Can you clarify the steps in the code above? How come your code and the code below performs same things? Actually everyting is the same but offsetting values.

[/COLOR]DoSelect Case ActiveCell
    Case "R": ActiveCell.Offset(0, 1).Select
    Case "D": ActiveCell.Offset(1, 0).Select
    Case "U": ActiveCell.Offset(-1, 0).Select
    Case "L": ActiveCell.Offset(0, -1).Select
    Case Else: Exit Do
End Select
Loop[COLOR=#574123]

And see my coments besides the lines:

[/COLOR]Do
Select Case ActiveCell
    Case "R": ActiveCell(1, 2).Select  'active cell = E4. So it should move 1 row down and 2 column right, which is G5. G5 is empty, meaning it should end the loop.
    Case "D": ActiveCell(2).Select
    Case "L": ActiveCell(1, 0).Select
    Case "U": ActiveCell(0).Select
    Case Else: Exit Do
End Select
Loop[COLOR=#574123]

 

[footoo]

The code I posted uses the Range.Item Property : https://msdn.microsoft.com/en-us/vba/excel-vba/articles/range-item-property-excel
The "non-shorthand" version :

Do
Select Case ActiveCell
    Case "R": ActiveCell.Item(1, 2).Select
    Case "D": ActiveCell.Item(2, 1).Select
    Case "L": ActiveCell.Item(1, 0).Select
    Case "U": ActiveCell.Item(0, 1).Select
    Case Else: Exit Do
End Select
Loop