VBA to merge all files in folder not merging in correct order.

[Akbarov]

Hello Dear community,

I use following code to merge all Word documents in specific folder. "Generate"
All file names in specified folder are named as: Part1,Part2,Part3...
But it is merging with wrong order as : Part1,Part10,Part11 etc..
Can anyone help me to make it merge all with correct order please?

Thanks in advance,

Sub merge()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
 myPath = ThisDocument.Path & "\Generate\"
 
  strFile = Dir(myPath & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=myPath & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      '.InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
  objNewDoc.SaveAs myPath2
End Sub

 

[John_w]

All file names in specified folder are named as: Part1,Part2,Part3...

Untested, replace the While ... Wend loop with this:

  Dim n As Long
  n = 1
  While Dir(myPath & "Part" & n & ".docx") <> vbNullString
    Set objDoc = Documents.Open(FileName:=myPath & "Part" & n & ".docx")
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      '.InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
    n = n + 1
  Wend

 

[Akbarov]

Thank you so much John! Seems like everything working perfectly fine.