Vba to find text in sheet1 cell content from sheet2

[satish78]

HI Team,

I tried to find solution to my query on mrexcel forum.
unfortunately, I did not get exact solution to my query.
Here I need a macro to get the sheet2 ColumnB data into sheet1 ColumnE.
Macro to vlookup sheet2 ColumnA data in sheet1 ColumnC text if found get Sheet2 ColumnB data into Sheet1 ColumnE respectively.
Here is sample file attached.

Hightail Spaces

Hightail Spaces lets you send unlimited files, of any size, to anyone. Collaborate with your team and evolve your work.

spaces.hightail.com

 

[satish78]

Can anyone help with this?

 

[My Aswer Is This]

I understood this part:
Here I need a macro to get the sheet2 ColumnB data into sheet1 ColumnE.

But then you said:
Macro to vlookup sheet2 ColumnA data in sheet1 ColumnC text if found get Sheet2 ColumnB data into Sheet1 ColumnE respectively.
I surely do not understand the second part

 

[Alex Blakenburg]

How much data will you have on sheet1 (no of rows) ?
And is the list on Sheet2 likely to get much longer or is that roughly the sort of length it will stay at.

 

[Alex Blakenburg]

See if this works for you.
I had trouble with a couple of you values in Sheet2 having an ascii code 160 instead of a space hence the replace char 160.

Sub TestAddData()

    Application.ScreenUpdating = False

    Dim shtData As Worksheet, shtLookup As Worksheet
    Dim rngData As Range
    Dim arrLookup As Variant
    Dim strLookup As Variant
    Dim i As Long
    
    Set shtData = Worksheets("Sheet1")
    Set shtLookup = Worksheets("Sheet2")
    
    Set rngData = shtData.Range("A1").CurrentRegion
    arrLookup = shtLookup.Range("A1").CurrentRegion.Value

    If shtData.FilterMode = True Then shtData.ShowAllData
    
    For i = 1 To UBound(arrLookup, 1)
        strLookup = arrLookup(i, 1)
        strLookup = Replace(strLookup, Chr(160), " ")
        rngData.AutoFilter Field:=3, Criteria1:="=*" & strLookup & "*", Operator:=xlAnd
        On Error Resume Next
            rngData.Columns(3).Offset(1, 2).Resize(rngData.Rows.Count - 1).SpecialCells(xlCellTypeVisible).Value = arrLookup(i, 2)
        On Error GoTo 0
        rngData.AutoFilter Field:=3
    Next i
    
    Application.ScreenUpdating = True
    
End Sub

 

[satish78]

See if this works for you.
I had trouble with a couple of you values in Sheet2 having an ascii code 160 instead of a space hence the replace char 160.

Sub TestAddData()

    Application.ScreenUpdating = False

    Dim shtData As Worksheet, shtLookup As Worksheet
    Dim rngData As Range
    Dim arrLookup As Variant
    Dim strLookup As Variant
    Dim i As Long
   
    Set shtData = Worksheets("Sheet1")
    Set shtLookup = Worksheets("Sheet2")
   
    Set rngData = shtData.Range("A1").CurrentRegion
    arrLookup = shtLookup.Range("A1").CurrentRegion.Value

    If shtData.FilterMode = True Then shtData.ShowAllData
   
    For i = 1 To UBound(arrLookup, 1)
        strLookup = arrLookup(i, 1)
        strLookup = Replace(strLookup, Chr(160), " ")
        rngData.AutoFilter Field:=3, Criteria1:="=*" & strLookup & "*", Operator:=xlAnd
        On Error Resume Next
            rngData.Columns(3).Offset(1, 2).Resize(rngData.Rows.Count - 1).SpecialCells(xlCellTypeVisible).Value = arrLookup(i, 2)
        On Error GoTo 0
        rngData.AutoFilter Field:=3
    Next i
   
    Application.ScreenUpdating = True
   
End Sub

Thanks Alex,
Working like charm.
I appreciate your understand to my query.

 

[Alex Blakenburg]

Thanks for letting me know. Glad I could help.