vba to delete table row

[Beneindias]

Hi guys,

I have a file where I have an inputbox, where the user types "MyInputMatriculaMaiusculas" values.
This variable is then used to o through a table and delete the row, where this value is in the second column.

Or, at least, that was the goal, because, in reality, this code is doing nothing..
can anybody help me?

This code is suposed to go to "Tabelas Apoio" sheet, and go to "Viaturas" table, look for the number plate in the second column of said table and then, delete that same row.

What am I doing wrong here?

Dim tblA As ListObject
Dim a As Long

Set tblA = Worksheets("Tabelas Apoio").ListObjects("Viaturas")
For a = tblA.ListRows.Count To 1 Step -1
  If tblA.DataBodyRange(a, 2) = MyInputMatriculaMaiusculas Then
    tblA.ListRows(a).Delete
  End If
Next a

First tried this solution, but it didn't work too:

For a = Worksheets("Tabelas Apoio").ListObjects("Viaturas").ListRows.Count To 1 Step -1
  If Cells(a, 2).Value = MyInputMatriculaMaiusculas Then
    Cells(a, 2).EntireRow.Delete
  End If
Next a

 

[Rovex]

with this data....

To iterate from the bottom to the top and delete each row where the PID value is 2, run this

try this

Sub DelLine()
Dim ws As Worksheet
Dim lo As ListObject
Dim r As ListRow
Dim lCounter As Long

Set ws = ThisWorkbook.Sheets("Sheet3") 'sheetname is imaginatively titles Sheet3

Set lo = ws.ListObjects(1) 'it's the only listobject on the tab

For lCounter = lo.DataBodyRange.Rows.Count To 1 Step -1
Set r = lo.ListRows(lCounter)
If r.Range(1, 1) = 2 Then
r.Delete
End If

Next lCounter

End Sub

 

[Beneindias]

with this data....
View attachment 114180
To iterate from the bottom to the top and delete each row where the PID value is 2, run this

try this

Sub DelLine()
Dim ws As Worksheet
Dim lo As ListObject
Dim r As ListRow
Dim lCounter As Long

Set ws = ThisWorkbook.Sheets("Sheet3") 'sheetname is imaginatively titles Sheet3

Set lo = ws.ListObjects(1) 'it's the only listobject on the tab

For lCounter = lo.DataBodyRange.Rows.Count To 1 Step -1
Set r = lo.ListRows(lCounter)
If r.Range(1, 1) = 2 Then
r.Delete
End If

Next lCounter

End Sub

Adapted your code to my reality, and at least it deleted a row on the table, but it was the wrong one.

Here it is my code:

Dim tblA As ListObject
Dim a As Long
Dim rA As ListRow

Set tblA = Worksheets("Tabelas Apoio").ListObjects("Viaturas")
    For a = tblA.DataBodyRange.Rows.Count To 1 Step -1
        Set rA = tblA.ListRows(a)
        If rA.Range(a, 2) = MyInputMatriculaMaiusculas Then
            rA.Delete
        End If
    Next a

Here is part of my data:
(I'm trying to delete an entire row, when the value in column G (second column of my table) is the same that I'm looking for)

km veiculos_V6.xlsm
	F	G	H
6	C. Custos	Matricula	Descrição
7	001-012	50-68-TJ	FORD TRANSIT
8	001-025	11-LJ-08	RENAULT CLIO
9	001-027	84-LM-03	ISUZU
Tabelas Apoio

 

[Alex Blakenburg]

Your code in Post#1 worked fine for me.
In your latest code in Post#3, change the if statement to this:
rA is already using the row reference and you now want the same row ie 1 but the 2nd column.

        If rA.Range(1, 2) = MyInputMatriculaMaiusculas Then

 

[Beneindias]

Your code in Post#1 worked fine for me.
In your latest code in Post#3, change the if statement to this:
rA is already using the row reference and you now want the same row ie 1 but the 2nd column.

        If rA.Range(1, 2) = MyInputMatriculaMaiusculas Then

Yeap, that worked.

Still dont know why my code from post#1 didn't do anything, but it's working now.

Thank you @Rovex and @Alex Blakenburg

 

[Alex Blakenburg]

Just an FYI, this is case sensitive:
If rA.Range(1, 2) = MyInputMatriculaMaiusculas Then
Some options are:
1) If UCase(rA.Range(1, 2)) = UCase(MyInputMatriculaMaiusculas) Then
2) If StrComp(rA.Range(1, 2), MyInputMatriculaMaiusculas, vbTextCompare) = 0 Then