vba sum values in row for several rows

[Gtabtr1]

Hi all,
Addition has never been so frustrating.

I have many, many rows of numbers across several columns. The number of columns and rows will both vary. Values will begin in column B in each row. Would like to avoid loops, too many rows.

Dim lcol as Long
Dim fcol as Long
Dim rrow as Long
lcol = cells(1,columns.count).End(xlToLeft).Column
fcol = (lcol + 1)
rrow=Range("A" & Rows.Count).End(xUp).Row

With Range(Cells(2,fcol),Cells(rrow.fcol)) 'this is the range for results, tested and ok.
.formula = "=sum(" & Cells(2,2).Address & ":" & Cells(2,lcol).Address & ") "
.Value = .Value
End With

I get the answer for the first row in all rows in range.
Help Please.

 

[Fluff]

Try

Dim lcol As Long
Dim fcol As Long
Dim rrow As Long
lcol = Cells(1, Columns.Count).End(xlToLeft).Column
fcol = (lcol + 1)
rrow = Range("A" & Rows.Count).End(xlUp).Row

With Range(Cells(2, fcol), Cells(rrow, fcol)) 'this is the range for results, tested and ok.
.Formula = "=sum(" & Cells(2, 2).Address(0, 0) & ":" & Cells(2, lcol).Address(0, 0) & ") "
.Value = .Value
End With

 

[Gtabtr1]

Thank you Fluff. I appreciate your help!!!!! Couldn't do what I do without the board's help.
Have a great weekend.

 

[Fluff]

Have a good weekend yourself.
For reference a slightly easier way would be

With Range(Cells(2, fcol), Cells(rrow, fcol)) 'this is the range for results, tested and ok.
.FormulaR1C1 = "=sum(rc2,rc[-1])"
.Value = .Value
End With

 

[Rick Rothstein]

Have a good weekend yourself.
For reference a slightly easier way would be

With Range(Cells(2, fcol), Cells(rrow, fcol)) 'this is the range for results, tested and ok.
.FormulaR1C1 = "=sum(rc2,rc[-1])"
.Value = .Value
End With

You can also do it directly without placing the formula in the cells only to have to then equate values with themselves...

Dim LastCol As Long, OutCol As Long, LastRow As Long
LastRow = Cells(Rows.Count, "A").End(xlUp).Row
LastCol = Cells(1, Columns.Count).End(xlToLeft).Column
With Range(Cells(2, LastCol + 1), Cells(LastRow, LastCol + 1))
  .Value = Evaluate("IF({1},SUBTOTAL(9,OFFSET(B1,ROW(A1:A" & LastRow - 1 & "),0,1," & LastCol - 1 & ")))")
End With