VBA String in cell to check box value

[Alexandra20]

Hello, I am trying to make this code work:

Private Sub commandB_Click()
If Cells(ActiveCell.Row, "G") = "Výtah" Then
realita.vytah.Value = True
End If

If Cells(ActiveCell.Row, "G") = "Konstrukce" Then
realita.konstrukce.Value = True
End If

............ other similar IF functions .............
userForm.Show
End Sub

It is supposed to open the user form with checkboxes named: "Výtah", "Konstrukce",... and many more, however, some of them should be already checked according to what is written in the active cell (in the column G).

BTW, the G column has the text string in this form - Výtah, Konstrukce, other words (it could be also blank or there could be only one option written, in that case, there is no comma).

Why is the code not working?

 

[DanteAmor]

I have the following question, "realita" is the name of your userform?
If yes then try this:

Private Sub commandB_Click()
  With Range("G" & ActiveCell.Row)
    If InStr(1, .Value, "Výtah") > 0 Then
      realita.vytah.Value = True
    End If
   
    If InStr(1, .Value, "Konstrukce") > 0 Then
      realita.konstrukce.Value = True
    End If
  End With
  '............ other similar IF functions .............
  'UserForm.Show
End Sub

Or For all your texts and checkbox

Private Sub commandB_Click()
  Dim txt As Variant, cbx As Variant
  Dim i As Long
  txt = Array("Výtah", "Konstrukce", "other")
  cbx = Array("vytah", "konstrukce", "Other")
  '
  For i = 0 To UBound(txt)
    If InStr(1, Range("G" & ActiveCell.Row).Value, txt(i)) > 0 Then
      realita.Controls(cbx(i)).Value = True
    End If
  Next
End Sub

 

[Alexandra20]

I have the following question, "realita" is the name of your userform?
If yes then try this:

Private Sub commandB_Click()
  With Range("G" & ActiveCell.Row)
    If InStr(1, .Value, "Výtah") > 0 Then
      realita.vytah.Value = True
    End If
  
    If InStr(1, .Value, "Konstrukce") > 0 Then
      realita.konstrukce.Value = True
    End If
  End With
  '............ other similar IF functions .............
  'UserForm.Show
End Sub

Or For all your texts and checkbox

Private Sub commandB_Click()
  Dim txt As Variant, cbx As Variant
  Dim i As Long
  txt = Array("Výtah", "Konstrukce", "other")
  cbx = Array("vytah", "konstrukce", "Other")
  '
  For i = 0 To UBound(txt)
    If InStr(1, Range("G" & ActiveCell.Row).Value, txt(i)) > 0 Then
      realita.Controls(cbx(i)).Value = True
    End If
  Next
End Sub

yes, the userform is "realita" I forgot to mention that but thanks a lot, everything works wonderfully

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.