vba sort array row by row

[montecarlo2012]

Hello.
I have an array B2:F9500 dynamic.

short example
this is what I have

this is what I am looking for

in other words, I need to sort in ascending order each row.
thanks.

 

[DanteAmor]

Try this:

Sub SortNums()
  Dim a As Variant, b As Variant
  Dim coll As Object
  Dim i As Long, j As Long
  
  a = Range("B2", Cells(Range("F" & Rows.Count).End(3).Row, Cells(2, Columns.Count).End(1).Column)).Value
  
  Set coll = CreateObject("System.Collections.ArrayList")
  For i = 1 To UBound(a)
    For j = 1 To UBound(a, 2)
      coll.Add a(i, j)
    Next
    coll.Sort
    For j = 0 To coll.Count - 1
      a(i, j + 1) = coll(j)
    Next
    coll.Clear
  Next
  Range("B2").Resize(UBound(a, 1), UBound(a, 2)).Value = a
End Sub

 

[alansidman]

Option Explicit

Sub SortLtoR()

Dim i As Long, lr As Long
lr = Range("A" & Rows.Count).End(xlUp).Row
For i = 1 To lr
    Range("A" & i & ":E" & i).Select
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add2 Key:=Range("A" & i & ":E" & i) _
        , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        
        With ActiveWorkbook.Worksheets("Sheet1").Sort
        .SetRange Range("A" & i & ":E" & i)
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlLeftToRight
        .SortMethod = xlPinYin
        .Apply
    End With
Next i
End Sub

 

[Peter_SSs]

Like this?

Sub Sort_By_Row()
  Dim rw As Range
  
  Application.ScreenUpdating = False
  For Each rw In Range("B2:F" & Range("B" & Rows.Count).End(xlUp).Row).Rows
    rw.Sort Key1:=rw, Order1:=xlAscending, Orientation:=xlLeftToRight
  Next rw
  Application.ScreenUpdating = True
End Sub

 

[montecarlo2012]

Peter_SSs, Thank you Sir, work perfect

 

[montecarlo2012]

Thank you DanteAmor. for your reply.

 

[montecarlo2012]

Alansidman, thank you for your reply.

 

[Peter_SSs]

Peter_SSs, Thank you Sir, work perfect

You're welcome. Thanks for the follow-up.