VBA - Set row height based on value in cells

[Spaztic]

Need help! The code I've tried is too far off to even show.

I'm looking for vba code that would:

• look at Column B to be NOT blank, AND
• look at Column C to contain 'X'
• IF this is true, the entire row height would be set to height = 75
• However, if row height is already greater than 75, it would leave the row alone (e.g. if someone already expanded the row to 100, it would stay at 100) This is the tricky part, in my opinion.
• NOTE: This would look through the entire worksheet and expand all rows that met the criteria

Thank you for ANY help you may have for me in advance!

Starts like this:

When the code is run, should look like this

 

[Joe4]

Try this code:

Sub SetRowHeight()

    Dim lr As Long
    Dim r As Long
    
    Application.ScreenUpdating = False
    
'   Find last row in column C with data
    lr = Cells(Rows.Count, "C").End(xlUp).Row
    
'   Loop through all rows
    For r = 1 To lr
'       See if column B not empty and C is "X"
        If Cells(r, "B") <> "" And Cells(r, "C") = "X" Then
'           See if height of row is < 75
            If Rows(r).RowHeight < 75 Then
'               Set row height to 75
                Rows(r).RowHeight = 75
            End If
        End If
    Next r
    
    Application.ScreenUpdating = True
    
End Sub

 

[Spaztic]

Thank you! This worked perfectly!

 

[Joe4]

You are welcome.
Glad I was able to help!