VBA: Send a specific Worksheet not the entire workbook

[bamaisgreat]

I have used the code below to Email a copy of a workbook. I would like it to only send a specific worksheet named "JOB FORM". Can this be done. Thanks as always

 'Sub Mail_Workbook_1()
' Works in Excel 2000, Excel 2002, Excel 2003, Excel 2007, Excel 2010, Outlook 2000, Outlook 2002, Outlook 2003, Outlook 2007, Outlook 2010.
' This example sends the last saved version of the Activeworkbook object .
    Dim OutApp As Object
    Dim OutMail As Object    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    On Error Resume Next
   ' Change the mail address and subject in the macro before you run it.
    With OutMail
        .To = "[EMAIL="operators@ggsteel.com"]operators@ggsteel.com[/EMAIL]"
        .CC = ""
        .BCC = ""
        .Subject = "ANGLELINE JOB Form"
        .Body = ""
        .Attachments.Add ActiveWorkbook.FullName
        ' You can add other files by uncommenting the following line.
        '.Attachments.Add ("C:\test.txt")
        ' In place of the following statement, you can use ".Display" to
        ' display the mail.
        .SEND
    End With
    On Error GoTo 0
    Set OutMail = Nothing
    Set OutApp = Nothing
    
    Application.Quit
     
End Sub

 

[Norie]

Try this.

 Sub Mail_Workbook_1()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim wbTemp As Workbook
    Dim strFilename As String
    
    ' copy 'JOB FORM' to it's own workbook
    ThisWorkbook.Worksheets("JOB FORM").Copy
    
    ' set reference to new workbook
    Set wbTemp = ActiveWorkbook
    
    ' save new workbook so it can be sent as attachment
    
    wbTemp.SaveAs ThisWorkbook.Path & "/" & "JobForm", XlFileFormat.xlOpenXMLWorkbook
    
    strFilename = wbTemp.FullName
    
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    On Error Resume Next
    With OutMail
        .To = "operators@ggsteel.com"
        .CC = ""
        .BCC = ""
        .Subject = "ANGLELINE JOB Form"
        .Body = ""
        .Attachments.Add strFilename
        .display
    End With
    On Error GoTo 0
    Set OutMail = Nothing
    Set OutApp = Nothing
    
    wbTemp.Close
    
    Kill strFilename
     
End Sub