VBA Save Copy As to specific folder

[decadence]

Hi, Is it possible to Save a copy of an active workbook to a specific folder as a CSV format file while using the dialog pop up? Also I have an issue where If I cancel then the active book name changes to False, can someone help please

Here is what I have at the moment which changes the active book name

Option Explicit
Dim varResult As Variant
Const StrPath As String = "C\User\Documents\"
Sub sbSaveExcelDialog()
    varResult = Application.GetSaveAsFilename(FileFilter:="CSV Files (*.csv), *.csv", Title:="Save As CSV", InitialFileName:=StrPath)
End Sub

 

[sergioMabres]

Hi deca,
I think to do this you need an other book to run the macro, so you can get back to your .xlsx file
Cheers
Sergio

 

[decadence]

I don't require the .xlsx file, The end user needs to save a copy of the workbook that they are using as a CSV file in a specific folder, I chose to use the dialog popup so they can save the filename as a specific name for each workbook they save.

 

[John_w]

Try this:

Public Sub Save_Workbook_Copy_As_CSV()

    Dim folderPath As String
    Dim csvFile As String
    
    folderPath = "C:\Users\username\Documents"
 
    csvFile = Application.GetSaveAsFilename(InitialFileName:=folderPath, _
                FileFilter:="CSV Files (*.csv), *.csv", Title:="Save As CSV")
 
    If csvFile <> "" And csvFile <> "False" Then
        Application.ScreenUpdating = False
        ActiveSheet.Copy
        On Error Resume Next
        ActiveWorkbook.SaveAs fileName:=csvFile, FileFormat:=xlCSV, _
            Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, CreateBackup:=False, ConflictResolution:=xlUserResolution
        On Error GoTo 0
        'Close .csv workbook, leaving original workbook open
        ActiveWorkbook.Close SaveChanges:=False
        Application.ScreenUpdating = True
    End If

End Sub

 

[decadence]

Brilliant, works perfectly, Thanks for your help