VBA: Run-time error 13: Type mismatch

[Strogg]

Hey everybody. Error 13 (type mismatch) occurs when I try to run this macro.
Nevertheless, I can't find out which data types are incompatible. Could you help me to find it out, please?

Here is the code.

Public Sub Macro1()
    Dim m, n, p As Double
    Dim x1, x2, xmin, z As Double
    m = InputBox("Input m", "Input", "")
    n = InputBox("Input n", "Input", "")
    p = InputBox("Input p", "Input", "")
    x1 = (m ^ 2 + n - Sqr(Abs(m * p))) / 10
    If m > 10 And m < 15 Then
    x2 = m + n
    Else
    x2 = p - m
    End If
    Dim usl As Boolean
    usl = x2 > x1
    If usl Then
        x1 = xmin
    Else
        x2 = xmin
    End If
    z = xmin + 15
    Dim answer As String
    answer = "x1 = " & "x2 = " & "xmin = " And "z = "
    MsgBox answer, "vbInforamtion", "Answer"
End Sub

 

[MrKowz]

The way you're dimming your variables isn't exactly correct. When you write a line like:

Dim m, n, p as Double

It's not dimming all of them as double, it's only dimming p as double. m and n are both being dimmed as variant here, which allows for non-numerical values.

Explicitly define each variable type:
Dim m as double, n as double, p as double

 

[RoryA]

Your Msgbox statement is wrong - it should be:

MsgBox answer, vbInformation, "Answer"

 

[Strogg]

It's not dimming all of them as double, it's only dimming p as double.

Your Msgbox statement is wrong

Oh my God. How could I forget about it? Sometimes I make really weird mistakes.
I've changed dimming and message box in proper way, but error still occurs.

 

[NdNoviceHlp]

Public Sub Macro1()
    Dim m As Double, n As Double, p As Double
    Dim x1 As Double, x2 As Double, xmin As Double, z As Double
    m = InputBox("Input m", "Input", "")
    n = InputBox("Input n", "Input", "")
    p = InputBox("Input p", "Input", "")
    x1 = (m ^ 2 + n - Sqr(Abs(m * p))) / 10
    If m > 10 And m < 15 Then
    x2 = m + n
    Else
    x2 = p - m
    End If
    Dim usl As Boolean
    usl = x2 > x1
    If usl Then
        x1 = xmin
    Else
        x2 = xmin
    End If
    z = xmin + 15
    Dim answer As String
    answer = "x1 = " & x1 & " x2 = " & x2 & " xmin = " & xmin & " z = " & z
    MsgBox answer, vbInformation, "Answer"
End Sub

Adjusted as suggested. Your answer provided no info and used "AND" instead of "&". HTH. Dave

 

[Strogg]

Now it works fine. Thank you guys for the help!