VBA: Referring to rows as ranges

[drluke]

I am trying to loop through all cells in a row (row 7 starting at column E to last used column) and copying the value in the cell below (row 8) if cell in row 7 does not equal zero.

I am not sure if I've written the code correctly for this. Would appreciate any advice.

Sub SummarizeData()    Dim LastCol As Integer
    
    Rows("2:" & Rows.Count).ClearContents
    Worksheets("Volume Allocation").Activate
    
    With ActiveSheet
        LastCol = .Cells(7, .Columns.Count).End(xlToLeft).Column
    End With
    
    For i = 7 To LastCol
        If Worksheet.Cells(7, i).Value <> 0 Then
             ActiveSheet.Cells.Range("8:i").Value.Copy Destination:=Sheets("Journal").Range("A1")
             PasteSpecial Paste:=xlPasteValues, Transpose:=True
        End If
    Next i
End Sub

 

[MARK858]

Try the code below on a copy of your workbook.

Please note that I can't tell by either your code or description what sheet the line in red is referring to.

Please also note that the code hasn't been tested.

Sub SummarizeData()
    Dim LastCol As Long, x As Long, i As Long
    Application.ScreenUpdating = False
    [COLOR="#FF0000"]Rows("2:" & Rows.Count).ClearContents[/COLOR]
    
    With Worksheets("Volume Allocation")
    
        LastCol = .Cells(7, .Columns.Count).End(xlToLeft).Column
        x = 1

        For i = 5 To LastCol
            If .Cells(7, i).Value <> 0 Then
                Sheets("Journal").Cells(x, "A").Value = .Cells(8, i).Value
                x = x + 1
            End If
        Next i
        
    End With
    
    Application.ScreenUpdating = True
End Sub

 

[jolivanes]

Not much different from above.

Sub Maybe()
Dim i As Long, sh2 As Worksheet
Set sh2 = Worksheets("Journal")
    For i = 5 To Cells(7, Columns.Count).End(xlToLeft).Column
        If Cells(7, i).Value <> 0 Then Cells(7, i).Offset(1).Copy sh2.Cells(Rows.Count, 1).End(xlUp).Offset(1)
    Next i
End Sub

 

[drluke]

Thank you both!! A cheeky follow-up question: how can I change the fill color of only the cells being copied when this macro is run (i.e. the copied cells in "Journal")