VBA - Referencing a jagged array index in For loop

[CRHAAG]

I have an array of arrays and am trying to cycle through it and run macros based on the index in the array. My code is as follows

Dim reportList As Variant  
'sheet, button, report
    reportList = Array( _
        Array("scpSumBox", "RPscopeOfWorkSummary", "Scope of Work Summary"), _
        Array("prpSumBox", "RPprpFixtures", "Proposed Fixture Summary"), _
        Array("exstSumBox", "RPexistingFixtures", "Existing Fixture Summary") _
        )
    
    'Cycle through list and create reports
    For i = 0 To UBound(reportList)
        If Sheets("REPORT").reportList(i)(0).Value = True Then
            Call reportList(i)(1)
        End If
        Next i

The debugger is highlighting Call reportList(i)(1) between the i and the 1 and saying:
Compile Error: Expected end of statement

The items in the array are as follows
Index 0 - name of a radio button
index 1 - name of a macro that creates a report
index 2 - name of the report that it will eventually create

Right now I am trying to get the For Loop to run the macro at the index in reportList

Any insight would be appreciated

 

[DanteAmor]

If radio buttons are Active X controls, then it could be.
Macros "prpSumBox"... must be in a module.

Sub test()
  Dim i As Long
  Dim reportList As Variant
  'sheet, button, report
  reportList = Array( _
    Array("scpSumBox", "RPscopeOfWorkSummary", "Scope of Work Summary"), _
    Array("prpSumBox", "RPprpFixtures", "Proposed Fixture Summary"), _
    Array("exstSumBox", "RPexistingFixtures", "Existing Fixture Summary"))
  
  'Cycle through list and create reports
  For i = 0 To UBound(reportList)
    If Sheets("REPORT").OLEObjects(reportList(i)(0)).Object.Value = True Then
      Run reportList(i)(1)
    End If
  Next i
End Sub

 

[CRHAAG]

If radio buttons are Active X controls, then it could be.
Macros "prpSumBox"... must be in a module.

Sub test()
  Dim i As Long
  Dim reportList As Variant
  'sheet, button, report
  reportList = Array( _
    Array("scpSumBox", "RPscopeOfWorkSummary", "Scope of Work Summary"), _
    Array("prpSumBox", "RPprpFixtures", "Proposed Fixture Summary"), _
    Array("exstSumBox", "RPexistingFixtures", "Existing Fixture Summary"))
 
  'Cycle through list and create reports
  For i = 0 To UBound(reportList)
    If Sheets("REPORT").OLEObjects(reportList(i)(0)).Object.Value = True Then
      Run reportList(i)(1)
    End If
  Next i
End Sub

That did the trick!!! Thanks so much

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.