VBA Range.copy does nothing - clipboard issues?

[RockandGrohl]

Hi all, got some super simple code here that's not working:

est.Activate
LastrowEst = est.Cells(Rows.Count, "B").End(xlUp).Row

Range("C12:C" & LastrowEst).Copy

When I execute the copy command, nothing happens - there's no bounding box around the range in the est sheet. I've tested on single ranges.

Manual copies work and I get the dashed line on the copied range.

Can anyone help with this? Thank you.

 

[RoryA]

Which module is the code in?

 

[RockandGrohl]

Which module is the code in?

It's in a Worksheet_Activate module:

Private Sub Worksheet_Activate()

'End Sub

Dim wb As Workbook
Dim ios As Worksheet, est As Worksheet, temp As Worksheet
Dim LastrowEst As Long, LastrowTemp As Long
Dim desc As String, CBS As String
Dim cost As Double

Set wb = ActiveWorkbook
Set ios = Sheets("Internal Only Summary")
Set est = Sheets("Estimate")

Application.ScreenUpdating = False
Application.EnableEvents = False

If ios.Range("CompletedEstimate") = "yes" Then
Exit Sub
End If

' Delete Temp sheet if one exists
On Error Resume Next
Application.DisplayAlerts = False
Worksheets("Temp").Delete
Application.DisplayAlerts = True
On Error GoTo 0

' Test if temp sheet exists
On Error Resume Next
Set temp = Worksheets("Temp")
On Error GoTo 0
' If sheet doesn't exist create
If temp Is Nothing Then
    Set temp = wb.Sheets.Add
    temp.Name = "Temp"
End If

est.Activate
LastrowEst = est.Cells(Rows.Count, "B").End(xlUp).Row

Range("C12:C" & LastrowEst).Copy

 

[RoryA]

That's what I figured. Your Range property refers to the sheet with the code in it, not the active sheet. You should use est.Range(...) instead.

 

[RockandGrohl]

That's what I figured. Your Range property refers to the sheet with the code in it, not the active sheet. You should use est.Range(...) instead.

O Rory, you are so wise.

I'll amend that, thanks chum.

Rory to the rescue.

AGAIN