VBA Question

[ChrisFoster]

Hi all,

I hope I'm posting in the correct section, please just move if I have.

Please can someone write me some code for VBA to use in Outlook?
I need to be able to run a macro to search the current folder (not whole mailbox) for all read emails. This is in place of manually clicking search, typing isread:yes, changing the folder to 'Current Folder'.

Kind regards,

Chris

 

[nguyendang]

The following VBA macro will search the current folder for all unread mails. It behaves as if you have typed the query string in the Instant Search user interface and clicked Search button.

Public Sub SearchForUnreadMails()
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType = olMailItem Then
        Dim objExpl As Outlook.Explorer
        Set objExpl = Application.ActiveExplorer
        objExpl.Search "isread:yes", olSearchScopeCurrentFolder
    End If
End Sub

However, the above VBA macro will only displays the search result in the Outlook GUI. To retrieve information about each unread mail (Body, Subject, or Attachment(s)), you can try the following macro:

Public Sub GetUnreadMailsInCurrentFolder()
    Dim objFolder As Outlook.Folder
    Set objFolder = Application.ActiveExplorer.CurrentFolder
    Dim strFilter As String
    strFilter = "@SQL=" & Quote("urn:schemas:httpmail:read") & "=0"
    Dim colItems As Outlook.Items
    Set colItems = objFolder.Items.Restrict(strFilter)
    If colItems.Count > 0 Then
        Dim objMail As Outlook.MailItem
        Set objMail = colItems.GetFirst
        Do While Not objMail Is Nothing
            'Do something with the search result
            Debug.Print objMail.Subject 'Print the mail subject
            Set objMail = colItems.GetNext
        Loop
    End If
End Sub

Private Function Quote(ByVal Text As String) As String
    Quote = Chr(34) & Text & Chr(34)
End Function

You may modify the code to suit your need.

 

[ChrisFoster]

The following VBA macro will search the current folder for all unread mails. It behaves as if you have typed the query string in the Instant Search user interface and clicked Search button.

Public Sub SearchForUnreadMails()
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType = olMailItem Then
        Dim objExpl As Outlook.Explorer
        Set objExpl = Application.ActiveExplorer
        objExpl.Search "isread:yes", olSearchScopeCurrentFolder
    End If
End Sub

Thanks - for this code it states that macros are disabled for this project. Any ideas? I have macros enabled on Outlook.

 

[nguyendang]

From the Developer tab on the ribbon, click the Macro Security button -> Macro Settings and check to see if the option "Enable all macros..." is checked.

 

[ChrisFoster]

From the Developer tab on the ribbon, click the Macro Security button -> Macro Settings and check to see if the option "Enable all macros..." is checked.
View attachment 93078

Yes I already have all macros enabled.

 

[nguyendang]

Yes I already have all macros enabled.

Then you need to restart Outlook for the changes to take effect.

 

[ChrisFoster]

Then you need to restart Outlook for the changes to take effect.

Thanks - that has worked