VBA problem

[Hacklin337]

Hello,
I need help with this code:

Sub OTWIERANIEXLS3()

Dim customerBook As Workbook
Dim filter As String
Dim caption As String
Dim customerFilename As String
Dim customerWorkbook As Workbook
Dim targetWorkbook As Workbook

Set targetWorkbook = Application.ActiveWorkbook

filter = "Text files (*.xls),*.xls"
caption = "Please select your route"
customerFilename = Application.GetOpenFilename(filter, , caption)

Set customerWorkbook = Application.Workbooks.Open(customerFilename)

Dim targetSheet As Worksheet
Set targetSheet = targetWorkbook.Worksheets(1)
Dim sourceSheet As Worksheet
Set sourceSheet = customerWorkbook.Worksheets(1)

targetSheet.Range("CA1", "CJ201").Value = sourceSheet.Range("A1", "J201").Value

customerWorkbook.Close

End Sub

I need this thing to work the same exact way but, when in the selection window i press nothing or cancel, nothing is copied (there is no selection error)
Thank you for any help

 

[dmt32]

Hi,
try this update to your code & see if does what you want

Sub OTWIERANIEXLS3()
    
    Dim filter              As String, caption As String
    Dim customerFilename    As Variant
    Dim customerWorkbook    As Workbook, targetWorkbook As Workbook
    Dim customerBook        As Workbook
    Dim targetSheet         As Worksheet, sourceSheet As Worksheet
    
    Set targetWorkbook = Application.ActiveWorkbook
    
    filter = "Text files (*.xls),*.xls"
    caption = "Please Select your route"
    customerFilename = Application.GetOpenFilename(filter, , caption)
    'cancel pressed
    If VarType(customerFilename) = vbBoolean Then Exit Sub
    
    Set customerWorkbook = Application.Workbooks.Open(customerFilename)
    
    Set targetSheet = targetWorkbook.Worksheets(1)
    
    Set sourceSheet = customerWorkbook.Worksheets(1)
    
    targetSheet.Range("CA1", "CJ201").Value = sourceSheet.Range("A1", "J201").Value
    
    customerWorkbook.Close
    
End Sub

Dave

 

[Hacklin337]

Thank you so much

 

[dmt32]

Thank you so much

welcome - appreciate the feedback

Dave