VBA Pivot Table Errors

[mreman81]

Hi all, I can't seem to figure out why this code is not working to create a pivot table. I'm using Excel 2013 and will be updating to 2019 soon.

When I get to the last line of code, I get Runtime Error 5: Invalid Procedure Call or Argument

Sub Auto_Pivot()

Dim PBook As Workbook
Dim PSheet As Worksheet
Dim DSheet As Worksheet
Dim PCache As PivotCache
Dim PTable As PivotTable
Dim DRange As String
Dim ShtName As String
Dim LastRow As Integer
Dim LastColumn As Integer


Sheets.Add Before:=ActiveSheet
Set PSheet = ActiveSheet
PSheet.Name = "Preparer Summary"
ShtName = "Data"


Set PBook = ThisWorkbook
Set DSheet = Worksheets(ShtName)

LastColumn = DSheet.Cells(7, DSheet.Columns.Count).End(xlToLeft).Column
LastRow = DSheet.Cells(DSheet.Rows.Count, "A").End(xlUp).Row
DRange = Range(Cells(6, 1), Cells(LastRow, LastColumn)).Address

'Define Pivot Cache
Set PCache = PBook.PivotCaches.Create(xlDatabase, ShtName & "!" & DRange, xlPivotTableVersion15)

'Insert Blank Pivot Table
Set PTable = PCache.CreatePivotTable _
(TableDestination:=PSheet.Cells(2, 2), TableName:="PrepSumPivot")

End Sub

 

[Alex Blakenburg]

I could not get the code to fail on my machine so I went looking.

In the post linked below, the suggestion from @JackDanIce is to try changing the version reference from xlPivotTableVersion15 to xlPivotTableVersion14
Macro runs on one computer and get run time error 5 on another

 

[mreman81]

@Alex Blakenburg that didn't seem to work either ? So I went the unsophisticated route of using the macro recorder and then just modified the code for the variables I created and it worked... Go figure LOL... Here's the code that worked:

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
        ShtName & "!" & DRange, Version:=xlPivotTableVersion15).CreatePivotTable _
        TableDestination:=PSheet.Cells(2, 2), TableName:="PrepSumPivot", DefaultVersion _
        :=xlPivotTableVersion15

If you have any insights into the "why" behind this, I would greatly appreciate it. As of now I didn't really learn anything, just to rely on the macro recorder more hahaha

 

[Alex Blakenburg]

Thanks for the update. I will have another look at it tomorrow. Not sure I will find anything since it worked fine for me.

 

[RoryA]

Is the code in a different workbook to the pivot table and data? That would cause the error you describe, and explain why your fix worked, since you refer to ActiveWorkbook not ThisWorkbook when creating the pivot cache.

 

[mreman81]

@RoryA Yes, the code itself is in the PERSONAL.XLB workbook where I'm storing macros. Maybe that's the issue?

 

[RoryA]

Yes - in your original code you should have used:

Set PBook = ActiveWorkbook

 

[mreman81]

@RoryA Got it!!! That makes sense :0) Thanks for the assist guys...

 

[smozgur]

@RoryA Got it!!! That makes sense :0) Thanks for the assist guys...

@mreman81 - What makes sense is mostly the answer of the question. I was going to switch the answer when I first read this thread earlier today, but wanted to see your reply first. Since we all know what was the actual problem now and have a solution with explanation, I switched the solution post with the obvious one to help future readers better.

 

[mreman81]

@smozgur Ah yes, definitely...Thanks for changing that!!!