vba object variable or with block variable not set (How to move on???)

[MrMarcAnthony]

Hello, I'm only trying to have the macro move on to the next (Selection.Find) if no value is found instead of crashing

Please help.

thank you!

Sheets("Funded Bankwide").Select
Columns("A:A").Select
Selection.Find(What:="Inside Sales", After:=ActiveCell, LookIn:=xlFormulas, _
LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False).Activate
Rows(ActiveCell.Row).Select
Selection.RowHeight = 18
With Selection
.HorizontalAlignment = xlGeneral
.VerticalAlignment = xlCenter
.WrapText = False
.Orientation = 0
.AddIndent = False
.IndentLevel = 0
.ShrinkToFit = False
.ReadingOrder = xlContext
.MergeCells = False
End With
Selection.Font.Bold = True
With Selection.Font
.Name = "ARIAL"
.Size = 12
.Strikethrough = False
.Superscript = False
.Subscript = False
.OutlineFont = False
.Shadow = False
.Underline = xlUnderlineStyleNone
.Color = -16777216
.TintAndShade = 0
.ThemeFont = xlThemeFontNone
End With
With Selection.Font
.Color = -65536
.TintAndShade = 0
End With
Columns("A:A").Select
Selection.Find(What:="Others", After:=ActiveCell, LookIn:=xlFormulas, _
LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False).Activate

 

[mumps]

Can you explain in words what you are trying to do? Be as detailed as possible.

 

[MrMarcAnthony]

of course

When I run the macro and it doesn't find "Inside Sales" ... it crashes and shows this error message (VBA object variable or with block variable not set.
then I have to debug it buy stepping into the macro at the next Select.find which is "Others". I would like for the macro to just move on to the next Select.find automatically.

thx

 

[mumps]

Do you want to find every occurrence of "Inside Sales" and "Others"? If so, what do you want to do when you find them?

 

[MrMarcAnthony]

thanks mumps...

Both Inside Sales & Others will only occur once in my data set in (A:A) I would like for the macro to move on if " String Text" isn't located

 

[mumps]

Try:

Sub Test()
    Application.ScreenUpdating = False
    Dim myArray As Variant, i As Long, val As Range
    myArray = Array("Inside Sales", "Others")
    For i = LBound(myArray) To UBound(myArray)
        Set val = Sheets("Funded Bankwide").Range("A:A").Find(myArray(i), LookIn:=xlValues, lookat:=xlWhole)
        If Not val Is Nothing Then
            With val
                .RowHeight = 18
                .HorizontalAlignment = xlGeneral
                .VerticalAlignment = xlCenter
            End With
            With val.Font
                .Bold = True
                .Name = "ARIAL"
                .Size = 12
                .Color = -65536
            End With
        End If
    Next i
    Application.ScreenUpdating = True
End Sub

 

[MrMarcAnthony]

I'm still working with your Coding mumps, Thanks for all of your help and attention.

Marc

 

[mumps]

You are very welcome. Please let me know if it works for you.