VBA move selection to different sheet and insert based on selection

[MrGeek1]

Hi,

I am working on below to move a selection of rows in sheet x given the string "Dead" to a next sheet (sheet y) and subsequently insert the amount of rows selected in that next sheet. Can anyone give an example how to show this in the code?

Many thanks!


Sub Moverow()


Dim i As Long


For i = 2 To 100
If Worksheets("x").Range("B" & i) = "Dead" Then
Range(Range("B" & i), Range("B" & i).End(xlToRight)).Select
Selection.Copy
Worksheets("y").Select
Rows("2:2").Select
Selection.Insert Shift:=xlDown
End If
Next
End Sub

 

[Fluff]

Do you have any data in col A, or is it completely blank?

 

[MrGeek1]

Col A is blank, data starts in Col B

 

[Fluff]

In that case try

Sub MrGeek1()
   With Sheets("x")
      .Range("B1").AutoFilter 1, "Dead"
      .AutoFilter.Range.Offset(1).EntireRow.Copy Sheets("y").Range("B" & Rows.count).End(xlUp).Offset(1, -1)
      .AutoFilterMode = False
   End With
End Sub

 

[MrGeek1]

Thanks, that works. As a next step do you also know how the copied selection rows can be erased from sheet x after pasting it in sheet y?

 

[Fluff]

Like

Sub MrGeek1()
   With Sheets("x")
      .Range("B1").AutoFilter 1, "Dead"
      .AutoFilter.Range.Offset(1).EntireRow.Copy Sheets("y").Range("B" & Rows.count).End(xlUp).Offset(1, -1)
      .AutoFilter.Range.Offset(1).EntireRow.Delete
      .AutoFilterMode = False
   End With
End Sub

 

[MrGeek1]

I notice that my macro button jumps from sheet x to the specified sheet y after pressing the macro button. Do you have any clue why that is? Thanks

 

[Fluff]

Probably because it's not in row 1