VBA- Making Log/History

[pressure]

Hi Guys!

I have a sheet that is going to be used every day and i want to press a button and cut today's data and copy in a history sheet. Im kinda new to VBA but was able to cut and paste the data of the day successfully but when i press the button to log another day, the data overwrite the last one, im not being able to paste it in the next blank row.

So i select A11, press Ctrl + Shift Right and Down to select all the data

.

And pasted it in the other sheet

How do i make it paste in the next blank space everytime?

My VBA looks like this right now

-------------------------------------------------------
Range("A11").Select
Range(Selection, Selection.End(xlDown)).Select
Range(Selection, Selection.End(xlToRight)).Select
Selection.Cut

Sheets("Historico").Select
Range("A2").Select
ActiveSheet.Paste
Sheets("Gerenciamento").Select
Application.CutCopyMode = False

 

[Vathana]

You should avoid using Select unless you need it because it might cause unexpected error, e.g. you don't need to select a sheet/range to copy or paste value.
Also you should always specify of which sheet "Range" refers to.

Anyway can you try this,. Change "shDest" and "shSource" as your sheets.

Sub CutRange()

    Dim r As Range, startRange As Range, destRange As Range
  
    'Set Destination Range = the next empty row of "A" on sheet "shDest"

    Set destRange = ThisWorkbook.Worksheets("shDest").Range("A" & Rows.Count).End(xlUp).Offset(1)
  
    With ThisWorkbook.Worksheets("shSource")

        'Set r = A11 to the last row/column of sheet "shSource" - Then cut it to destRange

        Set startRange = .Range("A11")
        Set r = .Range(startRange, startRange.End(xlDown).End(xlToRight))
        r.Cut destRange
      
    End With
  
End Sub