VBA loop - Quick question

[kgkev]

I am stepping through and deleting marked rows in my sheet. If I miss the header row the macro runs but fails to delete one highlighted row.

If I include my header, I get a run time error.

I have fixed it my including i = 1 before the loop
...but I cannot get my head around my it fails.

This one missed one of the flagged "DEL" rows"

 Set rng = Sheets("Stage 2").Range("[COLOR=#ff0000]F2[/COLOR]", Sheets("Stage 2").Range("F5000").End(xlUp))
    
    For counter = 1 To rng.Rows.Count
        If rng.Cells(i) = "DEL" Then
            rng.Cells(i).EntireRow.Delete
        Else
            i = i + 1
        End If
    Next

This one gives a runtime error

 Set rng = Sheets("Stage 2").Range("[COLOR=#ff0000]F1[/COLOR]", Sheets("Stage 2").Range("F5000").End(xlUp))
    
    For counter = 1 To rng.Rows.Count
        If rng.Cells(i) = "DEL" Then
            rng.Cells(i).EntireRow.Delete
        Else
            i = i + 1
        End If
    Next

This one works

 Set rng = Sheets("Stage 2").Range("[COLOR=#ff0000]F1[/COLOR]", Sheets("Stage 2").Range("F5000").End(xlUp))
   [COLOR=#ff0000] i = 1[/COLOR]
    For counter = 1 To rng.Rows.Count
        If rng.Cells(i) = "DEL" Then
            rng.Cells(i).EntireRow.Delete
        Else
            i = i + 1
        End If
    Next

 

[Fluff]

When deleting rows it's best to work from bottom to top like

   Dim i As Long
   With Sheets("Stage 2")
      For i = .Range("F" & Rows.Count).End(xlUp).Row To 2 Step -1
         If .Range("F" & i).Value = "DEL" Then .Rows(i).Delete
      Next i
   End With

Or without looping

   With Sheets("Stage 2")
      If .AutoFilterMode Then .AutoFilterMode = False
      .Range("F1:F5000").AutoFilter 1, "DEL"
      .AutoFilter.Range.Offset(1).EntireRow.Delete
      .AutoFilterMode = False
   End With