VBA - Input Box prompt upon finding a blank cell

[AM2014]

Hi,
<o></o>
I am struggling to create a VBA code that prompts user input via an input box upon finding a blank cell in Column O, then continueing onto the next blank cell in Column O, again prompting an input box, then finishing when there are no further blank cells in the column. Also, I need to be able to see the cells adjacent to the blank cell in order to know what the input should be.

This post is similar to what I have been looking for, but doesn't exactly get the job done:

http://www.mrexcel.com/forum/excel-...cations-input-box-result-next-empty-cell.html

Thanks for any help!

 

[Warship]

Welcome to the board.
Play around w/ this:

Sub AM2014()
    Dim c As Range
    Dim LastRow As Long, i As Long
    Dim InputReply As Variant
    Dim InputMsg As String, SkipReply As String

    LastRow = Cells(Rows.Count, "N").End(xlUp).Row
    If Cells(Rows.Count, "P").End(xlUp) > LastRow Then
        LastRow = Cells(Rows.Count, "P").End(xlUp).Row
    End If
        
    For i = 1 To LastRow
        Set c = Cells(i, "O")
        If c = "" Then
            InputMsg = "[ " & c.Offset(, -1) & " ] ->    " & _
                "Enter value for: Col O  Row " & i & _
                "    <-[ " & c.Offset(, 1) & " ] "
                
            InputReply = InputBox(InputMsg)
            If InputReply = "" Then
                SkipReply = MsgBox("Skip Row " & i & " ?   (Cancel to abort)", _
                    vbYesNoCancel + vbDefaultButton2, "CONFIRM")
                If SkipReply = vbNo Then
                    i = i - 1
                ElseIf SkipReply = vbCancel Then
                    Exit Sub
                End If
            Else
                c = InputReply
            End If
        End If
    Next i
End Sub

 

[AM2014]

The code works perfectly with one little problem, I can't view the cell where I need to input my number. This is the most important part because otherwise I would have no clue what to input.

I did also notice that the blank cells are automatically entered with two spaces (" "), so I did enter spaces into these two lines:
If c = " " Then
If InputReply = " " Then

This code is a little advanced for me, so any further insight would be helpful. Thanks again!

 

[AM2014]

Actually, I got it all figured out! Thanks for all of your help!!