VBA Import Image

[JustinLock]

Hi all,

Having a few issues with Excel embedding the chosen image in excel for other user once file has been shared.

Images are not networked and I would need the document to save the designated images to the allocated cell(s) so that they can be viewed by anyone that downloads the document.

The issue is persistent regardless of protection status, however, I do need to maintain protection and don't want others to tamper with other object on the sheet.

Does anyone have any ideas?

Here's a snip of the code I have deployed so far:

Sub PAAT_SCREENSHOT_PROPOSAL()
Sheet4.Unprotect "DHH2fanclub"
Dim fNameAndPath As Variant
Dim img As Picture
fNameAndPath = Application.GetOpenFilename(Title:="SELECT JAUMET'S AWESOMENESS")
If fNameAndPath = False Then Exit Sub
    Set img = ActiveSheet.Pictures.Insert(fNameAndPath)
    With img
       'Resize Picture to fit in the range....
        .Left = Columns(11).Left
        .Top = Rows(2).Top
        .ShapeRange.LockAspectRatio = msoFalse
        .ShapeRange.Height = 330#
        .ShapeRange.Width = 816#
        .ShapeRange.Rotation = 0#
        .Placement = 1
       .PrintObject = True
    End With
    Sheet4.protect "DHH2fanclub"
End Sub

 

[jolivanes]

So what is the issue?
Explain what happens that you don't want to happen and when it happens.

 

[JustinLock]

So, When the document is viewed by a colleague after being sent by email, internal comms app or after uploading through a TT none of the images are visible.
I can only assume that the images aren't actually embedded but are merely linked and without the images being uploaded/networked they won't be viewable.

I need the images to become part of the document itself and short of including them within a zipped folder i'm a little stuck.

 

[JustinLock]

So what is the issue?
Explain what happens that you don't want to happen and when it happens.

So, When the document is viewed by a colleague after being sent by email, internal comms app or after uploading through a TT none of the images are visible.
I can only assume that the images aren't actually embedded but are merely linked and without the images being uploaded/networked they won't be viewable.

I need the images to become part of the document itself and short of including them within a zipped folder i'm a little stuck.

 

[JustinLock]

I have fixed my own issue.
After playing around a little I imported as a shape instead.

Now just need to be able to define the shape parameters accordingly but it doesn't want to resize...

Sub PAAT_SCREENSHOT_PROPOSAL()
Sheet4.Unprotect "DHH2fanclub"
Dim fNameAndPath As Variant
Dim img As Shape
fNameAndPath = Application.GetOpenFilename(Title:="SELECT JAUMET'S AWESOMENESS")
If fNameAndPath = False Then Exit Sub
    Set img = ActiveSheet.Shapes.AddPicture(Filename:=fNameAndPath, _
                                            LinkToFile:=False, SaveWithDocument:=True, _
                                            Left:=1, Top:=1, Width:=-1, Height:=-1)
    With img
       'Resize Picture to fit in the range....
        .Left = ActiveSheet.Range("K2").Left
        .Top = ActiveSheet.Range("K2").Top
        .Width = ActiveSheet.Range("K2:AA2").Width
        .Height = ActiveSheet.Range("K2:K23").Height
        .Placement = 1
        .LockAspectRatio = msoFalse
       .DrawingObject.PrintObject = True
    End With
    Sheet4.protect "DHH2fanclub"

 

[jolivanes]

Move your "LockAspectRatio = msoFalse" to before the resizing. It should be the first line after "With Img".


Regarding your fixed problem. I found this also. Just good to know.

For people landing here. Different versions of Excel handle this request differently,
Excel 2007 will insert the picture as an object, ie embed it in the workbook.
Excel 2010 will insert it as a link, which is bad times if you plan on sending it to anyone.
You need to change the insert to specify that it is embedded: Insert(Filename:= <path>, LinkToFile:= False, SaveWithDocument:= True)
Exactly what you did.

 

[JustinLock]

Move your "LockAspectRatio = msoFalse" to before the resizing. It should be the first line after "With Img".


Regarding your fixed problem. I found this also. Just good to know.

For people landing here. Different versions of Excel handle this request differently,
Excel 2007 will insert the picture as an object, ie embed it in the workbook.
Excel 2010 will insert it as a link, which is bad times if you plan on sending it to anyone.
You need to change the insert to specify that it is embedded: Insert(Filename:= <path>, LinkToFile:= False, SaveWithDocument:= True)
Exactly what you did.

Brilliant, such a simple fix lol.

Thanks for the help

 

[jolivanes]

Glad to hear all is well.
Good luck