VBA If statement not working

[danjames11]

I have made an If statement that, will make a date go 3 months on from the date you select on a drop down list, today, yesterday, 2 days ago, and 3 days ago. And when you click the button it changes the date on the cell 2 away from teh active cell. But for some reason the first 4 If statements work (Quarterly), and he last 4 (monthly) do not. Heres the code, can you help please?

Sub ClientPaid_Click()
If IsNumeric(Application.Match(ActiveCell.Value, Range("B13:B4000"), 0)) Then
If Range("D10") = "Quarterly" Then
If Range("L1") = "Today" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("O6").Value
Range("L1") = "Today"
Else
If Range("D10") = "Quarterly" Then
If Range("L1") = "Yesterday" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("O10").Value
Range("L1") = "Today"
Else
If Range("D10") = "Quarterly" Then
If Range("L1") = "2 days Ago" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("R6").Value
Range("L1") = "Today"
Else
If Range("D10") = "Quarterly" Then
If Range("L1") = "3 days Ago" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("R10").Value
Range("L1") = "Today"
Else
If Range("D10") = "Monthly" Then
If Range("L1") = "Today" Then
Range("C1").Select

Else
If Range("D10") = "Monthly" Then
If Range("L1") = "Yesterday" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("O11").Value
Range("L1") = "Today"
Else
If Range("D10") = "Monthly" Then
If Range("L1") = "2 days Ago" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("R7").Value
Range("L1") = "Today"
Else
If Range("D10") = "Monthly" Then
If Range("L1") = "3 days Ago" Then
ActiveCell.Range("C1").Select
ActiveCell = Range("R11").Value
Range("L1") = "Today"
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If
End If


Else
MsgBox "You need to Click on a Client Name, before you can select them as paid.", vbOKOnly, "Time For You Message - Paid Client"
End If
End Sub

All the quarterly ones work, and the monthly ones do not. What have I done wrong?

 

[Von Pookie]

Probably has something to do with the logic somewhere in your maze of nested If statements. Seriously, that thing is *not* pretty. It looks like it will only check for the "Monthly" option if it manages to get through all of your "Quarterly" statements.

You could make things a lot easier to read/understand (not to mention better coding) if you used Select Case statements. Not tested, but should give you some idea of what's possible:

Sub ClientPaid_Click()


If IsNumeric(Application.Match(ActiveCell.Value, Range("B13:B4000"), 0)) Then
    Select Case Range("D10").Value
        Case Is = "Quarterly"
            Select Case Range("L1").Value
                Case "Today"
                    Range("C1") = Range("O6").Value
                    Range("L1") = "Today"
                Case "Yesterday"
                    Range("C1") = Range("O10").Value
                    Range("L1") = "Today"
                Case "2 days Ago"
                    Range("C1") = Range("R6").Value
                    Range("L1") = "Today"
                Case "3 days Ago"
                    Range("C1") = Range("R10").Value
                    Range("L1") = "Today"
            End Select
        Case Is = "Monthly"
            Select Case Range("L1").Value
                Case Is = "Today"
                    Range("C1").Select
                Case Is = "Yesterday"
                    Range("C1") = Range("O11").Value
                    Range("L1") = "Today"
                Case Is = "2 days Ago"
                    Range("C1") = Range("R7").Value
                    Range("L1") = "Today"
                Case Is = "3 days Ago"
                    Range("C1") = Range("R11").Value
                    Range("L1") = "Today"
            End Select
    End Select
Else
    MsgBox "You need to Click on a Client Name, before you can select them as paid.", vbOKOnly, "Time For You Message - Paid Client"
End If

End Sub