VBA- Hide Multiple Tabs (sheets) based on list

[MrSourApple]

I have a a few lists on the tab "Master" in cells D3:D10, D12:D16, and D18:D24. These lists have the names of workbook tabs that I want hidden. Is there a quick way to hide all of these tabs so I don't have to do it manually?

This is the code I have to hide the first tab but would like a quick way to hide these tabs rather than copying this line for each tab:

Sheets(Sheets("Master").Range("D3").Value).Visible = False

 

[Joe4]

Try this macro:

Sub MyHideSheets()

    Dim myRange As Range
    Dim cell As Range
    
    Set myRange = Sheets("Master").Range("D3:D10, D12:D16, D18:D24")
    
    For Each cell In myRange
        If cell.Value <> "" Then
            Sheets(cell.Value).Visible = False
        End If
    Next cell
    
End Sub

 

[MrSourApple]

Thank you this worked perfectly, and since it is so simple I should be able to use it in other workbooks as well!

 

[Joe4]

Great! Glad to help!

One thing you may want to account for is what to do if there is a name in your list that does not match a sheet name. Currently, you would get an error. If you simply want to ignore those errors, you can do so with this slight modification:

Sub MyHideSheets()

    Dim myRange As Range
    Dim cell As Range
    
    Set myRange = Sheets("Master").Range("D3:D10, D12:D16, D18:D24")
    
    On Error Resume Next
    For Each cell In myRange
        If cell.Value <> "" Then
            Sheets(cell.Value).Visible = False
        End If
    Next cell
    On Error GoTo 0
    
End Sub

or else we could add some "error trapping" if you wanted it to return a message telling you that it cannot find a specific sheet name.

 

[MrSourApple]

Thank you for the error handling thought. I actually figured that out pretty quickly so I added that in right away.