VBA hidden row.

[jamiguel77]

hi all how to hide a row if in column F exist a cell that contains these word: "Mike"

if F5 = "Mike" and F18 = "Mike"

i want hide row 5 and 18, how to?

thanks

 

[alansidman]

Sub HideMike()
    Dim i As Long, lr As Long
    lr = Range("F" & Rows.Count).End(xlUp).Row
    For i = 1 To lr
        If Range("F" & i) = "Mike" Then
            Range("F" & i).EntireRow.Hidden = True
        End If
    Next i
End Sub

 

[rlv01]

Sub HideRows()
    Dim WS As Worksheet
    Dim RowsToHide As Range

    Set WS = ActiveSheet
    With WS
        If .AutoFilterMode Then .AutoFilterMode = False
        .Columns.AutoFilter Field:=.Columns("F").Column, Criteria1:="Mike"
        With .UsedRange
            Set RowsToHide = Application.Intersect(.SpecialCells(xlCellTypeVisible).EntireRow, .Resize(.Rows.Count - 1).Offset(1).EntireRow)
        End With
        If .AutoFilterMode Then .AutoFilterMode = False
        If Not RowsToHide Is Nothing Then
            RowsToHide.EntireRow.Hidden = True
        End If
    End With
End Sub

 

[Peter_SSs]

Simpler just to filter for "not equal to Mike"?

Sub HideMike()
  Columns("F").AutoFilter Field:=1, Criteria1:="<>Mike"
End Sub

@jamiguel77
Note that the AutoFilter suggestions do require that that row 1 of your sheet is a heading row with actual data below that (or at least that Mike cannot appear in cell F1). If you don't have a header row and you still want further suggestions, then post back with details.