VBA from Excel to Power Point

[thomasuponor]

Hi, On Excel sheet, I have 2 areas I want to copy to Power Point on 2 different slides.

Current macro works for 1 area but I'm having problem getting it to work with 2 areas.

Also asked here VBA from Excel to Power Point

Sub copyRangeToPresentation()
 
' Open New PowerPoint Instance
Set pptApp = CreateObject("PowerPoint.Application")
 
With pptApp
    ' Create A New Presentation
    Set ppt = .Presentations.Add
    ' Add A Blank Slide
    Set newSlide = ppt.Slides.Add(1, 12) ' ppLayoutBlank = 12
    ' Copy Range from Active Sheet in Excel
    ActiveSheet.Range1("B2:AI26").Copy
    ActiveSheet.Range2("AK2:AW26").Copy
    ' Paste to Powerpoint as an Image
    newSlide.Shapes.PasteSpecial DataType:=2  '2 = ppPasteEnhancedMetafile
    ' Switch to PowerPoint
    .Activate
End With
 
End Sub

 

[GWteB]

How about ...

Sub copyRangeToPresentation()
 
    ' Open New PowerPoint Instance
    Set pptApp = CreateObject("PowerPoint.Application")
    With pptApp
        ' Create A New Presentation
        Set ppt = .Presentations.Add
        With ppt
            ' Add A Blank Slide
            Set newSlide = .slides.Add(1, 12) ' ppLayoutBlank = 12
            ' Copy Range from Active Sheet in Excel
            ActiveSheet.Range("B2:AI26").Copy
            ' Paste to Powerpoint as an Image
            newSlide.Shapes.PasteSpecial DataType:=2 '2 = ppPasteEnhancedMetafile
            
            ' Add A Second Blank Slide
            Set newSlide = .slides.Add(.slides.Count + 1, 12) ' ppLayoutBlank = 12
            ' Copy Range from Active Sheet in Excel
            ActiveSheet.Range("AK2:AW26").Copy
            ' Paste to Powerpoint as an Image
            newSlide.Shapes.PasteSpecial DataType:=2 '2 = ppPasteEnhancedMetafile
            ' Switch to PowerPoint
        End With
        .Activate
    End With
End Sub