VBA Error Handling

[p4nny]

Hi

I was wondering whether there was a line of code that, On error would reattempt the step again.

Sometimes, I get a message "unable to save" sometimes which is a network issue. If I save for a second time (manually), it saves without any problems.

thisworkbook.save

If the above line fails, then repeat this step.

thanks in advance

 

[wideboydixon]

It's a long solution but it does allow you to re-try and waits between tries:

Dim startTime As Single
Dim tries As Long
Dim workbookSaved As Boolean

Const MAX_RETRIES = 5 ' Maximum number of re-tries
Const WAIT_SECONDS = 2 ' Time between tries

On Error Resume Next

tries = 0
workbookSaved = False
Do While True
    ' Should we give up?
    tries = tries + 1
    If tries > MAX_RETRIES Then Exit Do
    
    ' Try and save the workbook
    Err.Clear
    ThisWorkbook.Save
    If Err.Number = 0 Then
        workbookSaved = True
        Exit Do
    End If
    
    ' Wait 2 seconds
    startTime = Timer
    Do Until Timer - startTime > WAIT_SECONDS
        DoEvents
    Loop
Loop

' Saved?
If workbookSaved Then
    Debug.Print "Saved Successfully"
Else
    Debug.Print "Failed to save after " & MAX_RETRIES & " attempt(s)"
End If

WBD