VBA Error: Compile Error: Method or Data Member not found. When Pasting Excel Data into Word

[asgreek]

Hello,

I'm running into a VBA error: Compile Error: Method or Data Member not found. I'm trying to run my code which copies data from Excel and pastes it into Word FormFields. The error occurs on this line of code

For r = 3 To xlSht.Range("A" & .Rows.Count).End(xlUp).Row

and it specifically highlights

.Rows.

My entire code is:

Sub CC()
Dim wdApp As New Word.Application, wdDoc As Word.Document, wdRng As Word.Range
Dim xlSht As Worksheet, r As Long, c As Long
Set xlSht = ThisWorkbook.Sheets("Sheet1")
With wdApp
  .Visible = True
  For r = 3 To xlSht.Range("A" & .Rows.Count).End(xlUp).Row
    If xlSht.Range("A" & r).EntireRow.Hidden = False Then
      Set wdDoc = wdApp.Documents.Add(Template:="X:\abcde.docx")
      With wdDoc
        For c = 1 To 4
          If .Bookmarks("Text" & c).Exists Then
            .Bookmarks("Text" & c).Range.Fields(1).Result.Text = xlSht.Cells(r, c).Text
          Else
            MsgBox "Form field bookmark 'Text" & c & "' doesn't exist in:" & vbCr & _
              .AttachedTemplate.FullName
          End If
        Next
        .SaveAs2 Filename:="X:\abcde.docx", FileFormat:=wdFormatXMLDocument, AddToRecentFiles:=False
        .Close
      End With
    End If
  Next r
  .Quit
End With
End Sub

Any ideas why this is occurs? Thanks!

 

[RoryA]

Use xlSht.Rows.Count. The Word.Application doesn't have a Rows property.

 

[asgreek]

Use xlSht.Rows.Count. The Word.Application doesn't have a Rows property.

Wow, thank you! I'm running into the same problem with the

If .Bookmarks("Text" & c).Exists Then

, the Exists part of the code is highlighted which I'm guessing the Word.Application doesnt have this property as well. Do you know the alternative? Thank you so much!

 

[RoryA]

That's not the right syntax. It's:

If .Bookmarks.Exists("Text" & c) Then