Vba Enlarge & Resize Image

[muhammad susanto]

hi all..
i have code to enlarge image & resize, the code work properly but i want to adding Msg "Select one picture to enlarge" when running the code:
here this code:

Dim shp As Shape
    Dim big As Single, small As Single
    Dim shpDouH As Double, shpDouOriH As Double
    big = 1.5
    small = 0.5
    On Error Resume Next
    Set shp = ActiveSheet.Shapes(Application.Caller)
    With shp
        shpDouH = .Height
        .ScaleHeight 1, msoTrue, msoScaleFromTopLeft
        shpDouOriH = .Height
    
        If Round(shpDouH / shpDouOriH, 2) = big Then
            .ScaleHeight small, msoTrue, msoScaleFromTopLeft
            .ScaleWidth small, msoTrue, msoScaleFromTopLeft
            .ZOrder msoSendToBack
        Else
            .ScaleHeight big, msoTrue, msoScaleFromTopLeft
            .ScaleWidth big, msoTrue, msoScaleFromTopLeft
            .ZOrder msoBringToFront
        End If
    End With
End Sub

how to make it?

any help, greatly appreciated..

.sst

 

[Yongle]

Sub ReSizeImage()
    Dim shp As Shape
    Dim big As Single, small As Single
    Dim shpDouH As Double, shpDouOriH As Double
    big = 1.5
    small = 0.5
'is an image selected?
    On Error Resume Next: Set shp = ActiveSheet.Shapes(Selection.Name): On Error GoTo 0
    If shp Is Nothing Then GoTo Handling
    If shp.Type <> msoPicture Then GoTo Handling
'resize
    With shp
        shpDouH = .Height
        .ScaleHeight 1, msoTrue, msoScaleFromTopLeft
        shpDouOriH = .Height
    
        If Round(shpDouH / shpDouOriH, 2) = big Then
            .ScaleHeight small, msoTrue, msoScaleFromTopLeft
            .ScaleWidth small, msoTrue, msoScaleFromTopLeft
            .ZOrder msoSendToBack
        Else
            .ScaleHeight big, msoTrue, msoScaleFromTopLeft
            .ScaleWidth big, msoTrue, msoScaleFromTopLeft
            .ZOrder msoBringToFront
        End If
    End With
Exit Sub
Handling:
MsgBox "Please select a picture first", vbExclamation, ""
End Sub

 

[muhammad susanto]

hi Yongle, working well....
thank you so much...you're always coming

 

[Yongle]

This is not a good English phrase - "you're always coming" - it has a different meaning to what you think!
In future perhaps "Thank you" is enough

 

[BigDawg15]

LOL Yongle, True!

 

[muhammad susanto]

This is not a good English phrase - "you're always coming" - it has a different meaning to what you think!
In future perhaps "Thank you" is enough

ok, sorry Yongle, thank you.