VBA date related copy and paste - same workbook

[dnorm]

Hi All

I am trying to transfer data from sheet 1 "report" in cells I11:V11 (fixed) and the date for this report is located in K1 to the corresponding date on sheet "Daily Data Input" to cells C:P (rows constantly change) where the dates are located in B:B (the entire year is listed here).
The data is to be copied as values only as the "report" sheet is formulated (I dragged the data to one side to simplify things).
I have tried several variations of other peoples code and tried in vain to adapt them to my needs.

this will be added to an existing macros to run from a button (this part I can do).

 

[dnorm]

I should add that I am currently using excel 2007 & 2010 in building this report (2010 primary)

 

[Fluff]

How about

Sub CopyToDate()

   Dim Fnd As Range
   Dim Dte As Date
   
   Dte = Sheets("Report").Range("K1").Value
   
   Set Fnd = Sheets("Daily Data Input").Columns(2).Find(Dte, , , , , , , , False)
   If Fnd Is Nothing Then
      MsgBox Dte & " Not found"
      Exit Sub
   End If
   Fnd.Offset(, 1).Resize(, 14).Value = Sheets("Report").Range("I11:V11").Value
      
End Sub

 

[dnorm]

How about

Sub CopyToDate()

   Dim Fnd As Range
   Dim Dte As Date
   
   Dte = Sheets("Report").Range("K1").Value
   
   Set Fnd = Sheets("Daily Data Input").Columns(2).Find(Dte, , , , , , , , False)
   If Fnd Is Nothing Then
      MsgBox Dte & " Not found"
      Exit Sub
   End If
   Fnd.Offset(, 1).Resize(, 14).Value = Sheets("Report").Range("I11:V11").Value
      
End Sub

Works a treat, you LEGEND! thanks!

 

[Fluff]

Glad to help & thanks for the feedback