VBA copy Tab info to Header - Output shows as 'Tab]'

[GD03]

I've got the following VBA in a macro

It should copy the tab name from my excel worksheet and paste it into a string on the left header
It should also paste 'page x of x Pages' at the bottom of each page

For both of these the text copies OK but the Tab bit shows as 'TAB]' and the 'Page &[Page] of &[Pages]' shows as written here until I open and click on the header manually then it does what I want it to
How can I get the MACRO to do the open/close bit for me .... or to just do it properly in the first place?

With ActiveSheet.PageSetup

.LeftHeader = "Station Workings" & vbCr & "&[Tab]" & vbCr

.RightHeader = "(Re-formatted by on " & Format(Now(), "D MMM YY)")

.CenterFooter = "Page &[Page] of &[Pages]" & vbCr

End With

 

[John_w]

Try this macro:

Public Sub Page_Setup()

    Application.PrintCommunication = False
    With ActiveSheet.PageSetup
        .LeftHeader = "Station Workings" & vbLf & "&A"
        .RightHeader = "(Reformatted by " & Environ("USERNAME") & " on &D)"
        .CenterFooter = "Page &P of &N"
    End With
    Application.PrintCommunication = True
    
End Sub

 

[GD03]

Try this macro:

Public Sub Page_Setup()

    Application.PrintCommunication = False
    With ActiveSheet.PageSetup
        .LeftHeader = "Station Workings" & vbLf & "&A"
        .RightHeader = "(Reformatted by " & Environ("USERNAME") & " on &D)"
        .CenterFooter = "Page &P of &N"
    End With
    Application.PrintCommunication = True
   
End Sub

Thanks @John_w

Worked perfectly when the header starts off blank but if there's already something in the header (the .leftHeader in this case) it won't replace that text.
The other two which start off blank work fine with the above, cheers


Lee

 

[John_w]

I get the same issue. This seems to fix it:

Public Sub Page_Setup()

    With ActiveSheet.PageSetup
        .LeftHeader = ""
        .CenterHeader = ""
        .RightHeader = ""
        .LeftFooter = ""
        .CenterFooter = ""
        .RightFooter = ""
    End With
    Application.PrintCommunication = False
    With ActiveSheet.PageSetup
        .LeftHeader = "Station Workings" & vbLf & "&A"
        .RightHeader = "(Reformatted by " & Environ("USERNAME") & " on &D)"
        .CenterFooter = "Page &P of &N"
    End With
    Application.PrintCommunication = True
    
End Sub