VBA Code to save with a user specified directory and file name

[Joven76]

So what I'm wanting to to may be rather simple, but I'm having a difficult time finding the answer. I have a file of tracking numbers that is client specific. What I want to do is create a macro where the user will specify the client name and a file directory, and the macro uses this information to save the file in the directory with the specified client name and date.

What I'd like to do is have the macro pull up the saveas window, but already have the name generated, so all the user has to do is specify the file destination. How do I go about doing this?

 

[mumps]

Try:

Sub SaveFile()
    Dim fName As String
    Dim sPath As String
    fName = InputBox("Enter a client name.")
    If fName = "" Then Exit Sub
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        .Show
        If .SelectedItems.Count > 0 Then
            sPath = .SelectedItems(1)
            Application.DisplayAlerts = False
            ActiveWorkbook.SaveAs Filename:=sPath & Application.PathSeparator & fName & Replace(Date, "/", "-"), FileFormat:=51
            Application.DisplayAlerts = True
            MsgBox ("The file has been saved with the name: " & fName)
        End If
    End With
End Sub

 

[Joven76]

Thanks mumps, it worked with one exception.

The code

[COLOR=#333333] MsgBox ("The file has been saved with the name: " & fName)[/COLOR]

only shows the fName that I input from the input box, not the whole file name with the date. How do I fix that?

 

[mumps]

Replace that line of code with this one:

MsgBox ("The file has been saved with the name: " & fName & Replace(Date, "/", "-"))

 

[Joven76]

Duh, why didn't I think of that. Thanks!

 

[mumps]

You are very welcome.