VBA code for email body to send a cells value

[slickster135]

I have this code that works fine but I would like the second email body to have the text that's in cells A2:A52 if any of the cells meet the code of >0 and <30. I am stumped on this one. Thanks for any help someone can offer.

 

[Sam_D_Ben]

Please check, Thank you!

Sub SendEmailOnOpen()
    Dim ws As Worksheet
    Dim cell As Range
    Dim emailSent As Boolean
    Dim emailAddress As String
    Dim emailSubject As String
    Dim emailBody As String
    Dim textList As String

    emailAddress = "abc@mail.com"
    emailSubject = "Alert: License Renewal"
    emailBody = "One or more licenses are within 30 days or less and require renewal:" & vbNewLine & vbNewLine
    textList = ""

    Set ws = ThisWorkbook.Sheets("License tracker")

    emailSent = False

    For Each cell In ws.Range("L2:L52")
        If cell.Value > 0 And cell.Value < 30 Then
            textList = textList & "- " & ws.Cells(cell.Row, 1).Value & vbNewLine
            emailSent = True
        End If
    Next cell

    If emailSent Then
        emailBody = emailBody & textList

        With CreateObject("Outlook.Application").CreateItem(0)
            .To = emailAddress
            .Subject = emailSubject
            .Body = emailBody
            .Send
        End With
    End If
End Sub

 

[slickster135]

Yes, it worked. Thank you so much!

 

[Sam_D_Ben]

Yes, it worked. Thank you so much!

Glad, we could asisst you !