VBA- Clear Dropdown List and Start in 1st Postion

[Grimm127]

Hi All you Guru's,

I need a little help.

I have 5 Dependent drop down Lists. Created from the Data Validation. I would like to reset the selections once the user decides to do another selection. I created this code below. The idea is the if the user makes the 5 selections and if he chooses to start over he can go to the top Dropdown select another option and it would reset the other drop downs to the first positions. If the 1st drop down is doesn't change and user selects to change the 2nd drop down the other 3 drop down fields reset to 1st position so on and so forth. It works an it doesn't Please help.

Private Sub Worksheet_Change_DD1(ByVal Target As Range)
    
    Application.EnableEvents = False
        If Target.Address = "$A$1" And Target.Validation.Type = 3 Then
            Target.Offset(1, 0).Value = "SPORT"
            Target.Offset(2, 0).Value = "ALL"
            Target.Offset(3, 0).Value = "ALL"
            Target.Offset(4, 0).Value = "ALL"
    End If
    Application.EnableEvents = True

End Sub

Private Sub Worksheet_Change_DD2(ByVal Target As Range)
 
    Application.EnableEvents = False
    If Target.Address = "$A$2" And Target.Validation.Type = 3 Then
        Target.Offset(1, 0).Value = "ALL"
        Target.Offset(2, 0).Value = "ALL"
        Target.Offset(3, 0).Value = "ALL"
    End If
    Application.EnableEvents = True

End Sub

Private Sub Worksheet_Change_DD3(ByVal Target As Range)
   
    Application.EnableEvents = False
    If Target.Address = "$A$3" And Target.Validation.Type = 3 Then
        Target.Offset(1, 0).Value = "ALL"
        Target.Offset(2, 0).Value = "ALL"
    End If
    Application.EnableEvents = True

End Sub
Private Sub Worksheet_Change_DD4(ByVal Target As Range)
   
    Application.EnableEvents = False
    If Target.Address = "$A$4" And Target.Validation.Type = 3 Then
        Target.Offset(1, 0).Value = "ALL"
    End If
    Application.EnableEvents = True

End Sub

 

[Fluff]

What exactly do you mean by

It works an it doesn't

Also how are you calling those subs?

 

[Fluff]

Is this what you're after?

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.CountLarge > 1 Then Exit Sub
   Application.EnableEvents = False
   If Target.Address = "$A$1" And Target.Validation.Type = 3 Then
      Target.Offset(1, 0).Value = "SPORT"
      Target.Offset(2, 0).Value = "ALL"
      Target.Offset(3, 0).Value = "ALL"
      Target.Offset(4, 0).Value = "ALL"
   ElseIf Target.Address = "$A$2" And Target.Validation.Type = 3 Then
      Target.Offset(1, 0).Value = "ALL"
      Target.Offset(2, 0).Value = "ALL"
      Target.Offset(3, 0).Value = "ALL"
   ElseIf Target.Address = "$A$3" And Target.Validation.Type = 3 Then
      Target.Offset(1, 0).Value = "ALL"
      Target.Offset(2, 0).Value = "ALL"
   ElseIf Target.Address = "$A$4" And Target.Validation.Type = 3 Then
      Target.Offset(1, 0).Value = "ALL"
   End If
   Application.EnableEvents = True
End Sub

 

[Grimm127]

@Fluff,
Its perfect! Thank you! I couldn't picture in my head to set it up but now thanks to you it works great! Thank you again!

 

[Fluff]

Glad to help & thanks for the feedback