VBA Batch convert to PDF

[floggingmolly]

I have a macro that batch converts word documents to PDF. It works, but sometimes the word documents are in both .doc and .docx. Is there a way to alter the code so it will do both extensions? I tried to alter the code but it was changing .doc to PDF and .docx to PDFX. Any help would be appreciated. Below is the code I am using.

Sub ConvertMultipleWordToPDF()
 
Application.ScreenUpdating = False
Application.DisplayAlerts = False
 
Dim OpenSourceFolder As Object, OpenTargetFolder As Object
Dim SelectedWordFilesFolder As String, SelectedPdfFilesFolder As String
Dim InputWordFile As String, OutputPdfFile As String
 
 
Dim objWordApp As Word.Application
Dim objMyWordFile As Word.Document
Set objWordApp = CreateObject("Word.Application")
 
 
Set OpenSourceFolder = Application.FileDialog(msoFileDialogFolderPicker)
Set OpenTargetFolder = Application.FileDialog(msoFileDialogFolderPicker)
 
'Select input file folder
MsgBox ("Select input folder where word files are stored")
Set OpenSourceFolder = Application.FileDialog(msoFileDialogFolderPicker)
 
If OpenSourceFolder.Show = -1 Then
SelectedWordFilesFolder = OpenSourceFolder.SelectedItems(1)
End If
 
 
If SelectedWordFilesFolder = "" Then
MsgBox "No input folder selected, code will exit"
Exit Sub
End If
 
 
AppActivate Application.Caption
 
'Select output file folder
MsgBox ("Select output folder where PDF files are stored")
If OpenTargetFolder.Show = -1 Then
SelectedPdfFilesFolder = OpenTargetFolder.SelectedItems(1)
End If
 
 
If SelectedPdfFilesFolder = "" Then
MsgBox "No output folder selected, code will exit"
Exit Sub
End If
 
 
 
'Looping through only word files in input file folder
InputWordFile = Dir(SelectedWordFilesFolder & "\*.doc")

While InputWordFile <> ""
          
Set objMyWordFile = objWordApp.Documents.Open(SelectedWordFilesFolder & "\" & InputWordFile)
objWordApp.Visible = True
OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")

objWordApp.ActiveDocument.ExportAsFixedFormat OutputFileName:=OutputPdfFile, ExportFormat:=wdExportFormatPDF
      
objMyWordFile.Close
InputWordFile = Dir
Wend
 
objWordApp.Documents.Application.Quit
 
End Sub

 

[DanteAmor]

Change this line:
OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")

For this:
OutputPdfFile = SelectedPdfFilesFolder & "\" & Left(objMyWordFile.Name, InStrRev(objMyWordFile.Name, ".") - 1) & ".pdf"

 

[floggingmolly]

Change this line:
OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")

For this:
OutputPdfFile = SelectedPdfFilesFolder & "\" & Left(objMyWordFile.Name, InStrRev(objMyWordFile.Name, ".") - 1) & ".pdf"

I tried this but it didn't work. The .docx were saved as PDF but the .doc files it skipped and they weren't saved.

 

[DanteAmor]

Try this
Change this line:
OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")

For these

  If LCase(Right(objMyWordFile.Name, 1)) = "x" Then
    OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "docx", "pdf")
  Else
    OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")
  End If

 

[floggingmolly]

Try this
Change this line:
OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")

For these

  If LCase(Right(objMyWordFile.Name, 1)) = "x" Then
    OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "docx", "pdf")
  Else
    OutputPdfFile = SelectedPdfFilesFolder & "\" & Replace(objMyWordFile.Name, "doc", "pdf")
  End If

This worked but I had to add another line InputWordFile = Dir(SelectedWordFilesFolder & "\*.doc")

 

[floggingmolly]

This worked but I had to add another line InputWordFile = Dir(SelectedWordFilesFolder & "\*.doc")

Thank you all for your help. Much appreciated

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.

 

[DeMoNloK]

I'm glad to help you. Thanks for the feedback.

I just tried this and getting the user-defined type not supported. Is it have to do with the version of windows I'm using?

 

[DanteAmor]

Do you have the problem on this line?

Dim objWordApp As Word.Application

In the VBA menu select the Tools / Reference option and mark the reference:
Microsoft Word nn.0 Object Library

Note: nn is the version of your office