Using VBA to paste chart into PowerPoint

[merce33]

Can anyone tell me why the following code is generating this error:

Run time error ‘-2147188160 (80048420)’:

Slides (unknown member): invalid request. Clipboard is empty or contains data which may not be pasted here.

Sub testPPTcopyPaste()
    
    Dim wkbk As Workbook
    Dim sht As Worksheet
    Dim chrt As Chart
    Dim pptApp As PowerPoint.Application
    Dim pptStart As PowerPoint.Application
    Dim pptPres As PowerPoint.Presentation
    
    Set wkbk = ThisWorkbook
    Set sht = wkbk.Sheets("pivot table")
    
    
    
    Set pptStart = CreateObject("PowerPoint.Application")
    Set pptApp = GetObject(, "PowerPoint.Application")
    pptApp.Visible = True
    
    'create a new document
    Set pptPres = pptApp.Presentations.Add
    pptPres.Slides.Add(Index:=1, Layout:=ppLayoutTitle).Select
    
    pptPres.Slides(1).Shapes.Range(Array("Rectangle 2", "Rectangle 3")).Delete
    wkbk.Activate
    
    wkbk.Charts(1).ChartArea.Copy
    pptPres.Slides.Paste pptPres.Slides.Count
        
End Sub

The error comes from the very last line where I am trying to Paste the data. The XL workbook shows the graph as being in the "copied" state, and then if i go to PPT and press CTRL+V the graph pastes just fine.
Any suggestions?

Thanks.
Mike

 

[TazRMan]

Look here.

http://www.mrexcel.com/board2/viewtopic.php?t=145036&highlight=chart+powerpoint

 

[Jon Peltier]

This is redundant, you don't need two PowerPoint.Application object variables:

    Set pptStart = CreateObject("PowerPoint.Application") 
    Set pptApp = GetObject(, "PowerPoint.Application")

use this instead:

    On Error Resume Next
    ' Check whether PowerPoint is running
    Set PPApp = GetObject(, "PowerPoint.Application")
    If PPApp Is Nothing Then
        ' PowerPoint is not running, create new instance
        Set PPApp = CreateObject("PowerPoint.Application")
        PPApp.Visible = True
    End If
    On Error GoTo 0

your syntax is twisted:

    pptPres.Slides.Paste pptPres.Slides.Count

should be

    pptPres.Slides(pptPres.Slides.Count).Paste

or

    pptPres.Slides(pptPres.Slides.Count).Shapes.Paste