Using VBA to create wildcard filter for multiple criteria

[MisterBeee]

Hey guys, I'm new to using VBA, but I now know autofilter will only allow 2 sets of criteria for searching, and will not work w/wildcards (*). Here's the array function I tried to use that obviously didn't work.

ActiveSheet.Range("$A$10").CurrentRegion.AutoFilter Field:=2, Criteria1:= _
Array("1.3.0704.*", "1.4.0704.*", "1.4.0753.*", "1.4.0755.*"), Operator:=xlFilterValues

Can someone help me with the right code that will allow me to use wildcards to filter on multiple criteria? Thanks.

 

[Fluff]

As you have said, when using wild cards you are limited to two criteria. You will need to have a look at advanced filter.
http://www.contextures.com/exceladvancedfiltervba.html
https://www.thespreadsheetguru.com/...automate-filtering-on-and-out-specific-values

 

[Domenic]

Try...

Option Explicit

Sub test()


    Dim dicCriteria As Object
    Dim vData As Variant
    Dim i As Long
    
    Set dicCriteria = CreateObject("Scripting.Dictionary")
    dicCriteria.CompareMode = 1 'vbTextCompare


    With ActiveSheet
        If .FilterMode Then .AutoFilterMode = False
        With .Range("A10").CurrentRegion
            vData = .Columns(2).Cells.Value
            For i = 2 To UBound(vData, 1) 'exclude headers and start from the second row of data
                If Not dicCriteria.Exists(vData(i, 1)) Then
                    Select Case True
                        Case vData(i, 1) Like "1.3.0704.*"
                            dicCriteria(vData(i, 1)) = ""
                        Case vData(i, 1) Like "1.4.0704.*"
                            dicCriteria(vData(i, 1)) = ""
                        Case vData(i, 1) Like "1.4.0753.*"
                            dicCriteria(vData(i, 1)) = ""
                        Case vData(i, 1) Like "1.4.0755.*"
                            dicCriteria(vData(i, 1)) = ""
                    End Select
                End If
            Next i
            If dicCriteria.Count > 0 Then
                .AutoFilter field:=2, Criteria1:=dicCriteria.Keys, Operator:=xlFilterValues
            Else
                MsgBox "No records found.", vbInformation
            End If
        End With
    End With

    Set dicCriteria = Nothing

End Sub

Hope this helps!