Userform VBA option button get selected option

[eduzs]

Hi there,
There's no easy way to get selected option of a option button in a Userform VBA besides read one by one is is true or false (checked or not)???
GroupName works only to avoid multiselection in the group? There's no "grupname.value" option.
Thanks

 

[lrobbo314]

In Access VBA you can get the value of the Frame the option buttons are in. But from what I've seen from digging around on the internet, Excel VBA isn't set up that way. This code should work for what you want to do though. These are all generic control names, so change those as needed.

Private Sub CommandButton1_Click()
For Each ctl In UserForm1.Controls
    If TypeName(ctl) = "OptionButton" Then
        If ctl.Value = True Then
            Select Case ctl.Caption
                Case "OptionButton1"
                    MsgBox "do something"
                Case "OptionButton2"
                    MsgBox "do something else"
            End Select
        End If
    End If
Next ctl
End Sub

 

[My Aswer Is This]

You can use this to check all Option Buttons in a UserForm.

Private Sub CommandButton1_Click()
'Modified  8/16/2019  11:41:28 PM  EDT
For Each Control In Me.Controls
    If TypeName(Control) = "OptionButton" And Control.Value = True Then
        MsgBox Control.Caption
    End If
Next
End Sub

 

[dmt32]

Hi,
If you just want to establish the status for a named group of controls (True / False) you could as an idea, create a function

See if following will do what you want

 Function GroupNameValue(ByVal Group As String, ByVal ControlType As String) As Boolean    
    Dim Ctrl As Control
    For Each Ctrl In Me.Controls
        If TypeName(Ctrl) = ControlType Then
         GroupNameValue = CBool(Ctrl.Object.GroupName = Group And Ctrl.Value)
         If GroupNameValue Then Exit Function
        End If
    Next Ctrl
End Function

You just pass the group name & type of control in the group

e.g.

 Private Sub CommandButton1_Click()   
  MsgBox GroupNameValue("G1", "OptionButton")
End Sub


Private Sub CommandButton2_Click()
  MsgBox GroupNameValue("G1", "CheckBox")
End Sub

Hope Helpful

Dave

 

[eduzs]

There's no single function that gives the selected option button?
Like: GroupNameValue("MyGroup")=3 (the 3rd option button ou the groupname "MyGroup" is checked (true))

 

[DanteAmor]

There's no single function that gives the selected option button?
Like: GroupNameValue("MyGroup")=3 (the 3rd option button ou the groupname "MyGroup" is checked (true))

Apparently there is not a single function.



This is an option without reviewing one by one, it only shows you the last one selected.

Option Explicit
Dim opSel As String


Private Sub CommandButton1_Click()
  MsgBox "Selected buton: " & opSel
End Sub


Private Sub OptionButton1_Click()
  opSel = OptionButton1.GroupName & " " & OptionButton1.Name
End Sub
Private Sub OptionButton2_Click()
  opSel = OptionButton2.GroupName & " " & OptionButton2.Name
End Sub
Private Sub OptionButton3_Click()
  opSel = OptionButton3.GroupName & " " & OptionButton3.Name
End Sub
Private Sub OptionButton4_Click()
  opSel = OptionButton4.GroupName & " " & OptionButton4.Name
End Sub
Private Sub OptionButton5_Click()
  opSel = OptionButton5.GroupName & " " & OptionButton5.Name
End Sub
Private Sub OptionButton6_Click()
  opSel = OptionButton6.GroupName & " " & OptionButton6.Name
End Sub

------------------------------------------------------------------------

Or this other option, shows you true if any optionbutton is selected.

Private Sub CommandButton2_Click()
  MsgBox OptionButton1 = OptionButton2 = OptionButton3
End Sub

 

[dmt32]

There's no single function that gives the selected option button?
Like: GroupNameValue("MyGroup")=3 (the 3rd option button ou the groupname "MyGroup" is checked (true))

Not as far as I am aware unless another here reading this thread can offer further insight.

All suggestions posted are workarounds & any one may offer something that will go a little way in helping you.

Dave