Userform listbox - recall selection

[Formula11]

Is it possible to recall the value selected (highlighted blue) in a userform listbox when form is shown again.
Below code uses arrays to show subfolders in a listbox.

Option Explicit

Private Sub UserForm_Initialize()
Dim file_system As Object, sub_folder As Object
Dim main_folder As String
Dim arr_path As Variant
Dim m As Long
    Set file_system = CreateObject("Scripting.FileSystemObject")
    main_folder = "C:\My Documents\" 'Change as required
    'Array Folderpaths
    m = 0
    ReDim arr_path(0)
    If file_system.FolderExists(main_folder) Then
        For Each sub_folder In file_system.GetFolder(main_folder).SubFolders
            arr_path(m) = file_system.GetAbsolutePathName(sub_folder)
            m = m + 1
            ReDim Preserve arr_path(m)
        Next sub_folder
    End If
    'Populate listbox
    For m = 0 To UBound(arr_path)
        ListBox1.AddItem arr_path(m)
    Next m
End Sub

 

[smozgur]

If you only want to make this work on the current session, then you can declare a public variable, and use it to store the existing selection as an integer value. It will be used during the current session.

The following goes into the Thisworkbook class module:

Option Explicit
Public selectedItem As Integer

Private Sub Workbook_Open()
    selectedItem = -1
End Sub

And this is the addition to your existing code including theChange event procedure of ListBox1 control.

Private Sub UserForm_Initialize()
    ' Your existing code
    
    ' Add the following
    If ThisWorkbook.selectedItem <> -1 And ListBox1.ListCount > ThisWorkbook.selectedItem Then
        ListBox1.Selected(ThisWorkbook.selectedItem) = True
    End If
End Sub

Private Sub ListBox1_Change()
    ThisWorkbook.selectedItem = ListBox1.ListIndex
End Sub

If you need to save the selection to make it available when it is opened on the same computer next time, then you can use GetSetting and SaveSetting statements to save the selection in the Windows registry.

Beyond this, if you want to save the selection with the workbook and even make it available on other computers, then you'll need to save the value in the workbook itself (somewhere hidden in a worksheet cell, or workbook property, etc.)

 

[Formula11]

Thanks smozgur, your code does work.
Cheers.

 

[smozgur]

Thanks smozgur, your code does work.
Cheers.

 

[smozgur]

I don't know what I was thinking, but obviously, I missed basic math. We don't need to initialize the public variable value in the Workbook_Open event procedure. The following is the optimized code - just in case:

The Thisworkbook class module:

Option Explicit
Public selectedItem As Integer

Userform:

Private Sub UserForm_Initialize()
    ' Your existing code
    
    ' Add the following
    If ThisWorkbook.selectedItem > 0 And ListBox1.ListCount > ThisWorkbook.selectedItem Then
        ListBox1.Selected(ThisWorkbook.selectedItem - 1) = True
    End If
End Sub

Private Sub ListBox1_Change()
    ThisWorkbook.selectedItem = ListBox1.ListIndex + 1
End Sub

 

[Formula11]

Thanks again smozgur, this works as well.