UserForm left and top - how to understand?

[vbaResearch]

Hello forum,
my display is 1980x1080
When I set UserForm1.Left = 0 it goes fine to the left of the screen, but... what is going next I do not understand...

The center of the screen should be ".Left = 960"
But when I set it to 960, the userform appears about 200 or 300 pixels further from the display center.

Then I found out that maximum value of left property which provides at least left edge visible on the screen is 1470. Why 1470???

My display is 1980 pixels wide, but form hides from the screen when value is greater than 1470. (As if there was a problem with scaling or something, but what if I open it on another PC with another display size)

So the question is why userforfm hides when left is more than 1470 but not 1980?

 

[Anthony47]

I don't ask "Why?", but use .Top, .Left, .Width and .Height to get the dimension of the working window:

Debug.Print "L:", Application.Left
Debug.Print "T:", Application.Top
Debug.Print "W:", Application.Width
Debug.Print "H:", Application.Height

Then you can play with userform position and size using its .Top, .Left and its .Zoom

 

[mikerickson]

I've found that placement and sizing code works weirdly when it is in the Initialize event, but works great in the Activate event.

 

[EXCEL MAX]

It's about scaling screen and userform width.
The screen have pixels as unit, userform have points as unit. Relation between them is 3/4.
Also, if you need do find center, move userform to the left for half of userform width.
Here is example.

Private Sub UserForm_Initialize()
   
   Dim vResolutionX As Integer, vUserFormWidth As Double, vCenter As Double
   
   StartUpPosition = 0
   vResolutionX = 1980
   vUserFormWidth = Width
   vCenter = vResolutionX * 0.75 / 2 - vUserFormWidth / 2
   Left = vCenter
   
End Sub

 

[vbaResearch]

I don't ask "Why?", but use .Top, .Left, .Width and .Height to get the dimension of the working window:

Debug.Print "L:", Application.Left
Debug.Print "T:", Application.Top
Debug.Print "W:", Application.Width
Debug.Print "H:", Application.Height

Then you can play with userform position and size using its .Top, .Left and its .Zoom

Thank you, for your answer, it is interesting, but it is about Excel application window, not about userform, the userform can be outside of application window,

I've found that placement and sizing code works weirdly when it is in the Initialize event, but works great in the Activate event.

Thank you, for your answer, but after I got understanding about points, I could position my userform as I wanted in initialize event too

It's about scaling screen and userform width.
The screen have pixels as unit, userform have points as unit. Relation between them is 3/4.
Also, if you need do find center, move userform to the left for half of userform width.
Here is example.

Private Sub UserForm_Initialize()
  
   Dim vResolutionX As Integer, vUserFormWidth As Double, vCenter As Double
  
   StartUpPosition = 0
   vResolutionX = 1980
   vUserFormWidth = Width
   vCenter = vResolutionX * 0.75 / 2 - vUserFormWidth / 2
   Left = vCenter
  
End Sub

Thank you for your answer, yeah, now I get it, the points... now I get an exact result (checked with a ruler ). Ough, using points is weird... so when positioning labels, they also use points? it is weird... ookay... Thank you, solved

 

[EXCEL MAX]

Thanks for feedback.
I'm glad you see the difference.

 

[Anthony47]

@vbaResearch
All what you have done is correct.
I meant that using Application.Top/Left/Width/Height you can get information about the available window.

For example I overlap Excel with the userform using the following code:

Private Sub UserForm_Activate()
Dim iW As Single, iH As Single, rZoom As Single
iW = Me.Width
iH = Me.Height
Me.Left = Application.Left
Me.Width = Application.Width
Me.Top = Application.Top
Me.Height = Application.Height
'
If Me.Width / iW < Me.Height / iH Then
    rZoom = Me.Width / iW
Else
    rZoom = Me.Height / iH
End If
Me.Zoom = rZoom * 100
End Sub

And this works whichever is the screen resolution, either with normal or maximized window.

And with this other code I move the userform at the far right of the Excel window:

Private Sub UserForm_Click()
Me.Left = Application.Width + Application.Left - 20
End Sub