Userform: Find date in worksheet and put data collected from Userform list box in the next empty rows

[chips]

I have a
Worksheet named ANAESData "ANAES Data Entry"
and a
userform named:
ufANData that has three list box
lbxDate (single option select) data from a named range rngDate which has 2 columns
lbxName (single option select) rngANAESNames
lbxShifts (Multi option select) rngShifts which has 2 columns

listboxes populate as planned

I have trouble inserting the data into the worksheet.

I have multiple tables for each day of the month. The date is at the top of the table. starting at L8 with the next date at q8 and the next at u8
I need to use the date selected in lbxDate to find the right row then add in the next blank row the shift data collected from lbxShifts
If there is more than one name selected then copy the shift data

	L	M	N	O	P	Q	R	S
8	wk1 14/6/2021					wk1 15/6/2021
9	code	Shift	Mon1 Name			code	shift	Tue2 Name
10	insert lbxShift col1	lbxShift col2	selected lbxName
	copied from above if multiple names are selected	copied from above if multiple names are selected	next lbxName

trying to code this is it possible?

 

[DanteAmor]

In cell C8 you literally have the text:
"wk1 14/6/2021"

In the lbxDate listbox, what is the date column, is it the first?
And how are the dates, for example: 14/06/2021

If all of the above is correct, then
Maybe some adjustments need to be made because you missed some information.

Change in the code "Sheet1" by the name of your sheet.

Private Sub CommandButton1_Click()
  Dim sDate As String, sName As String
  Dim i As Long, col As Long, lr As Long
  Dim f As Range
  Dim sh As Worksheet
 
  If lbxDate.ListIndex = -1 Then
    MsgBox "Select date"
    Exit Sub
  End If
  If lbxName.ListIndex = -1 Then
    MsgBox "Select Name"
    Exit Sub
  End If
  If lbxShifts.ListIndex = -1 Then
    MsgBox "Select Shifts"
    Exit Sub
  End If
  Set sh = Sheets("Sheet1")
 
  sDate = Format(CDate(lbxDate.Value), "d/m/yyyy")
  sName = lbxName.Value
  Set f = sh.Rows(8).Find(sDate, , xlValues, xlPart, , , False)
  If Not f Is Nothing Then
    col = f.Column
    lr = sh.Columns(col).Find("*", , xlValues, , xlByRows, xlPrevious).Row + 1
    For i = 0 To lbxShifts.ListCount - 1
      If lbxShifts.Selected(i) Then
        sh.Cells(lr, col).Value = lbxShifts.List(i, 0)
        sh.Cells(lr, col + 1).Value = lbxShifts.List(i, 1)
        sh.Cells(lr, col + 2).Value = sName
        lr = lr + 1
      End If
    Next
  Else
    MsgBox "Date " & sDate & " does not exist"
  End If
End Sub

 

[chips]

I really must thank you so much! My description of my problem was not well defined however you gave me the information and knowledge to make it work! I am so grateful!!

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.