Userform as search tool

[ExtraCheese]

So the situation is as following:
User adds entries with Userform, containing: ID, Name, Address, reference.

All the input data is stored in a different hidden tab.

Now I would want to create a function in a different userform where user can also search the data, for example he searches for the ID, and gets the correspondent name, address and reference. Each data entry is unique, so he should only get one result.

I have this code, but the search function does come up with the wrong results (ID nr; other address etc.).

Private Sub CommandButton1_Click()

Dim id As Long, rowcount As Integer, foundcell As Range

id = TextBox3.Value

rowcount = Sheets("Data").Cells(Rows.Count, 1).End(xlUp).Row

With Worksheets("Data").Range("A2:H" & rowcount)
Set foundcell = .Find(what:=id, LookIn:=xlValues)

If Not foundcell Is Nothing Then
TextBox1.Value = .Cells(foundcell.Column, 1)
TextBox2.Value = .Cells(foundcell.Column, 2)
TextBox4.Value = .Cells(foundcell.Column, 3)
TextBox5.Value = .Cells(foundcell.Column, 7)
TextBox6.Value = .Cells(foundcell.Column, 8)
TextBox7.Value = .Cells(foundcell.Column, 5)
TextBox8.Value = .Cells(foundcell.Column, 6)
Else
TextBox1.Value = ""
TextBox2.Value = ""
TextBox4.Value = ""
TextBox5.Value = ""
TextBox6.Value = ""
TextBox7.Value = ""
TextBox8.Value = ""

End If

End With
End Sub

 

[KOKOSEK]

I do not know that's the reason because we do not see layout of data but

.Cells(RowIndex, ColumnIndex)

so maybe should be

.Cells(1, foundcell.Column)

 

[ExtraCheese]

Thanks for your reply Kokosek.

Layout of data is:
Box - date - ID - ref - name - address - address 2 - pass nr.

I can't seem to locate the code you mentioned, where do I put it?

 

[Akuini]

Layout of data is:
Box - date - ID - ref - name - address - address 2 - pass nr.

So, ID is in col C, right?
Try:

Private Sub CommandButton1_Click()

Dim id As String, rowcount As Long, foundcell As Range
Dim n As Long
id = TextBox3.Value

If id <> "" Then
    With Worksheets("Data")
    'ID is in col C
    Set foundcell = .Columns("C").Find(What:=id, LookIn:=xlValues, lookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
        If Not foundcell Is Nothing Then
            n = foundcell.Row
            TextBox1.Value = .Cells(n, 1)
            TextBox2.Value = .Cells(n, 2)
            TextBox4.Value = .Cells(n, 3)
            TextBox5.Value = .Cells(n, 7)
            TextBox6.Value = .Cells(n, 8)
            TextBox7.Value = .Cells(n, 5)
            TextBox8.Value = .Cells(n, 6)
        Else
            TextBox1.Value = ""
            TextBox2.Value = ""
            TextBox4.Value = ""
            TextBox5.Value = ""
            TextBox6.Value = ""
            TextBox7.Value = ""
            TextBox8.Value = ""
        End If
    
    End With
End If
End Sub

 

[ExtraCheese]

Thanks, works like a charm!

 

[Akuini]

You're welcome, glad to help & thanks for the feedback.