Use excel as a clipboard

T

tyr443

New Member
Joined
Mar 4, 2016
Messages
34
Office Version
  1. 365
Platform
  1. Windows
I have a feeling this may require something other than just excel, but no idea what.
I would like that when I [highlight>> right click >> copy] a word it is automatically added to a cell in excel. Essentially using excel as a clipboard with a new cell for each copied piece of information.
Generally it would be for single words, I learn languages and often find myself copying and pasting a lot into excel tables, if possible I would like to reduce the time spent flicking back and forward.

Any ideas?
 

Excel Facts

Last used cell?
Press Ctrl+End to move to what Excel thinks is the last used cell.
Sort by date Sort by votes
What about adding a custom menu item (or bunch of items) to the right-click context menu? Also, just thinking out loud, but instead of having to click into the cell and selecting the word, what about using a shortcut or a ribbon button or context menu item to show a list of words in the cell from which you could select the desired word? Would that work?
 
Upvote 0
I am not sure I understand but, if what you mean is to use excel as a storage platform for clipboard data storage (text only), something similar to the office clipboard task pane, then the following might interest you.

Below is some code I wrote in the past and which I have slightly amended. It will keep a record of all text traffic happening in the windows clipboard and will automatically store all the clipboard data in a worksheet in a sequential order on the fly.

ExcelAsClipBoardStorage.xlsm


In a Standard Module:
VBA Code: 
Option Explicit

#If VBA7 Then
    #If Win64 Then
        Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongPtrA" (ByVal hwnd As LongLong, ByVal nIndex As Long, ByVal dwNewLong As LongLong) As LongLong
    #Else
        Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    #End If
    Private Declare PtrSafe Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As LongPtr, ByVal hwnd As LongPtr, ByVal Msg As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As LongPtr
    Private Declare PtrSafe Function CreateWindowEx Lib "user32" Alias "CreateWindowExA" (ByVal dwExStyle As Long, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As LongPtr, ByVal hMenu As LongPtr, ByVal hInstance As LongPtr, lpParam As Any) As LongPtr
    Private Declare PtrSafe Function DestroyWindow Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
    Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Long) As Long
    Private Declare PtrSafe Function GetClipboardSequenceNumber Lib "user32" () As Long
    Private Declare PtrSafe Function GetClipboardData Lib "user32" (ByVal wFormat As Long) As LongPtr
    Private Declare PtrSafe Function AddClipboardFormatListener Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function RemoveClipboardFormatListener Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function GlobalLock Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
    Private Declare PtrSafe Function GlobalUnlock Lib "kernel32" (ByVal hMem As LongPtr) As Long
    Private Declare PtrSafe Function lstrlenW Lib "kernel32.dll" (ByVal lpString As LongPtr) As Long
    Private Declare PtrSafe Function lstrcpyW Lib "kernel32.dll" (ByVal lpString1 As LongPtr, ByVal lpString2 As LongPtr) As Long
    Private Declare PtrSafe Function SetProp Lib "user32" Alias "SetPropA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal hData As LongPtr) As Long
    Private Declare PtrSafe Function GetProp Lib "user32" Alias "GetPropA" (ByVal hwnd As LongPtr, ByVal lpString As String) As LongPtr
    Private Declare PtrSafe Function RemoveProp Lib "user32" Alias "RemovePropA" (ByVal hwnd As LongPtr, ByVal lpString As String) As LongPtr
#Else
    Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Private Declare Function CreateWindowEx Lib "user32" Alias "CreateWindowExA" (ByVal dwExStyle As Long, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As Long, ByVal hMenu As Long, ByVal hInstance As Long, lpParam As Any) As Long
    Private Declare Function DestroyWindow Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function CloseClipboard Lib "user32" () As Long
    Private Declare Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Long) As Long
    Private Declare Function GetClipboardSequenceNumber Lib "user32" () As Long
    Private Declare Function GetClipboardData Lib "user32" (ByVal wFormat As Long) As Long
    Private Declare Function AddClipboardFormatListener Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function RemoveClipboardFormatListener Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
    Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long
    Private Declare Function lstrlenW Lib "kernel32.dll" (ByVal lpString As Long) As Long
    Private Declare Function lstrcpyW Lib "kernel32.dll" (ByVal lpString1 As Long, ByVal lpString2 As Long) As Long
    Private Declare Function SetProp Lib "user32" Alias "SetPropA" (ByVal hwnd As Long, ByVal lpString As String, ByVal hData As Long) As Long
    Private Declare Function GetProp Lib "user32" Alias "GetPropA" (ByVal hwnd As Long, ByVal lpString As String) As Long
    Private Declare Function RemoveProp Lib "user32" Alias "RemovePropA" (ByVal hwnd As Long, ByVal lpString As String) As Long
#End If

Private Const TARGET_SHEET = "Sheet1"  '<<== change sheet as required.


Sub Start()
    Call CreateClipWindow
End Sub

Sub Finish()
    Call CleanUp
End Sub


'_______________________________________ PRIVATE ROUTINES __________________________________________________

Private Sub CreateClipWindow()
    #If Win64 Then
      Dim lHiddenWnd As LongLong
    #Else
      Dim lHiddenWnd As Long
    #End If
    If GetProp(Application.hwnd, "HiddenWnd") = 0 Then
        lHiddenWnd = CreateWindowEx(0, "Static", vbNullString, 0, 0, 0, 0, 0, 0, 0, 0, 0)
        Call SetProp(Application.hwnd, "HiddenWnd", lHiddenWnd)
        Call AddClipboardFormatListener(lHiddenWnd)
        Call SubClassClipBoardWatcherWindow(lHiddenWnd)
    End If
End Sub

Private Sub CleanUp()
    Call RemoveClipboardFormatListener(GetProp(Application.hwnd, "HiddenWnd"))
    Call SubClassClipBoardWatcherWindow(GetProp(Application.hwnd, "HiddenWnd"), False)
    Call DestroyWindow(GetProp(Application.hwnd, "HiddenWnd"))
    Call RemoveProp(Application.hwnd, "HiddenWnd")
End Sub
  
#If Win64 Then
    Private Sub SubClassClipBoardWatcherWindow(ByVal hwnd As LongLong, Optional ByVal bSubclass As Boolean = True)
#Else
    Private Sub SubClassClipBoardWatcherWindow(ByVal hwnd As Long, Optional ByVal bSubclass As Boolean = True)
#End If
    Const GWL_WNDPROC = (-4)
    If bSubclass Then
        If GetProp(Application.hwnd, "PrevProcAddr") = 0 Then
            Call SetProp(Application.hwnd, "PrevProcAddr", _
                SetWindowLong(hwnd, GWL_WNDPROC, AddressOf ClipBoardWindowCallback))
        End If
    Else
        If GetProp(Application.hwnd, "PrevProcAddr") Then
            Call SetWindowLong(hwnd, GWL_WNDPROC, GetProp(Application.hwnd, "PrevProcAddr"))
            Call RemoveProp(Application.hwnd, "PrevProcAddr")
        End If
    End If
End Sub

#If Win64 Then
    Private Function ClipBoardWindowCallback( _
        ByVal hwnd As LongLong, _
        ByVal uMsg As Long, _
        ByVal wParam As LongLong, _
        ByVal lParam As LongLong _
    ) As LongLong
#Else
    Private Function ClipBoardWindowCallback( _
        ByVal hwnd As Long, _
        ByVal uMsg As Long, _
        ByVal wParam As Long, _
        ByVal lParam As Long _
    ) As Long
#End If

    Const WM_CLIPBOARDUPDATE = &H31D
    Static lPrevSerial As Long
    Dim sCurClipText As String
  
    Call SubClassClipBoardWatcherWindow(hwnd, False)
    If uMsg = WM_CLIPBOARDUPDATE Then
        If lPrevSerial <> GetClipboardSequenceNumber Then
            sCurClipText = GetClipText
            If Len(sCurClipText) Then
                If SheetExistes(TARGET_SHEET) Then
                    Call AddClipContentToSheet(Worksheets(TARGET_SHEET), sCurClipText)
                End If
            End If
            lPrevSerial = GetClipboardSequenceNumber
        End If
    End If
    Call SubClassClipBoardWatcherWindow(hwnd, True)
    ClipBoardWindowCallback = CallWindowProc(GetProp(Application.hwnd, "PrevProcAddr"), hwnd, uMsg, wParam, lParam)
End Function

Private Sub AddClipContentToSheet(ByVal Sh As Worksheet, ByVal sClipContent As String)
    With Sheet1.Cells(Rows.Count, 1).End(xlUp)
        .Offset(1) = .Offset(1).Row - 5
        .Offset(1, 1) = sClipContent
        .Offset(1, 2) = Format(Now, "hh:mm:ss")
    End With
End Sub

Private Function GetClipTextAPI() As String
    'Doesn't work if data is copied from within excel.
    'Func not used here ...kept for the record only.
    Const CF_UNICODETEXT = &HD&
    #If Win64 Then
        Dim lStrPtr As LongLong
    #Else
        Dim lStrPtr As Long
    #End If
  
    On Error GoTo errHandler
    Call OpenClipboard(0&)
    If IsClipboardFormatAvailable(CF_UNICODETEXT) Then
        lStrPtr = GetClipboardData(CF_UNICODETEXT)
        If lStrPtr Then
            GetClipTextAPI = String$(lstrlenW(lStrPtr), vbNullChar)
            lstrcpyW StrPtr(GetClipTextAPI), GlobalLock(lStrPtr)
            Call GlobalUnlock(lStrPtr)
        End If
    End If
errHandler:
    Call CloseClipboard
End Function

Private Function GetClipText() As String
    On Error Resume Next
    With CreateObject("htmlfile")
        With .ParentWindow.ClipboardData
            GetClipText = .GetData("Text")
        End With
    End With
End Function

Private Function SheetExistes(ByVal ShName As String) As Boolean
    On Error Resume Next
    SheetExistes = Not IsError(ThisWorkbook.Worksheets(ShName))
End Function

Private Sub Auto_Close()
    Call CleanUp
End Sub
 
Last edited:
Upvote 1
Jaafar Tribak said:
I am not sure I understand but, if what you mean is to use excel as a storage platform for clipboard data storage (text only), something similar to the office clipboard task pane, then the following might interest you.

Below is some code I wrote in the past and which I have slightly amended. It will keep a record of all text traffic happening in the windows clipboard and will automatically store all the clipboard data in a worksheet in a sequential order on the fly.

ExcelAsClipBoardStorage.xlsm


In a Standard Module:
VBA Code: 
Option Explicit

#If VBA7 Then
    #If Win64 Then
        Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongPtrA" (ByVal hwnd As LongLong, ByVal nIndex As Long, ByVal dwNewLong As LongLong) As LongLong
    #Else
        Private Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    #End If
    Private Declare PtrSafe Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As LongPtr, ByVal hwnd As LongPtr, ByVal Msg As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As LongPtr
    Private Declare PtrSafe Function CreateWindowEx Lib "user32" Alias "CreateWindowExA" (ByVal dwExStyle As Long, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As LongPtr, ByVal hMenu As LongPtr, ByVal hInstance As LongPtr, lpParam As Any) As LongPtr
    Private Declare PtrSafe Function DestroyWindow Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long
    Private Declare PtrSafe Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Long) As Long
    Private Declare PtrSafe Function GetClipboardSequenceNumber Lib "user32" () As Long
    Private Declare PtrSafe Function GetClipboardData Lib "user32" (ByVal wFormat As Long) As LongPtr
    Private Declare PtrSafe Function AddClipboardFormatListener Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function RemoveClipboardFormatListener Lib "user32" (ByVal hwnd As LongPtr) As Long
    Private Declare PtrSafe Function GlobalLock Lib "kernel32" (ByVal hMem As LongPtr) As LongPtr
    Private Declare PtrSafe Function GlobalUnlock Lib "kernel32" (ByVal hMem As LongPtr) As Long
    Private Declare PtrSafe Function lstrlenW Lib "kernel32.dll" (ByVal lpString As LongPtr) As Long
    Private Declare PtrSafe Function lstrcpyW Lib "kernel32.dll" (ByVal lpString1 As LongPtr, ByVal lpString2 As LongPtr) As Long
    Private Declare PtrSafe Function SetProp Lib "user32" Alias "SetPropA" (ByVal hwnd As LongPtr, ByVal lpString As String, ByVal hData As LongPtr) As Long
    Private Declare PtrSafe Function GetProp Lib "user32" Alias "GetPropA" (ByVal hwnd As LongPtr, ByVal lpString As String) As LongPtr
    Private Declare PtrSafe Function RemoveProp Lib "user32" Alias "RemovePropA" (ByVal hwnd As LongPtr, ByVal lpString As String) As LongPtr
#Else
    Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Private Declare Function CreateWindowEx Lib "user32" Alias "CreateWindowExA" (ByVal dwExStyle As Long, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As Long, ByVal hMenu As Long, ByVal hInstance As Long, lpParam As Any) As Long
    Private Declare Function DestroyWindow Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function CloseClipboard Lib "user32" () As Long
    Private Declare Function IsClipboardFormatAvailable Lib "user32" (ByVal wFormat As Long) As Long
    Private Declare Function GetClipboardSequenceNumber Lib "user32" () As Long
    Private Declare Function GetClipboardData Lib "user32" (ByVal wFormat As Long) As Long
    Private Declare Function AddClipboardFormatListener Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function RemoveClipboardFormatListener Lib "user32" (ByVal hwnd As Long) As Long
    Private Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) As Long
    Private Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) As Long
    Private Declare Function lstrlenW Lib "kernel32.dll" (ByVal lpString As Long) As Long
    Private Declare Function lstrcpyW Lib "kernel32.dll" (ByVal lpString1 As Long, ByVal lpString2 As Long) As Long
    Private Declare Function SetProp Lib "user32" Alias "SetPropA" (ByVal hwnd As Long, ByVal lpString As String, ByVal hData As Long) As Long
    Private Declare Function GetProp Lib "user32" Alias "GetPropA" (ByVal hwnd As Long, ByVal lpString As String) As Long
    Private Declare Function RemoveProp Lib "user32" Alias "RemovePropA" (ByVal hwnd As Long, ByVal lpString As String) As Long
#End If

Private Const TARGET_SHEET = "Sheet1"  '<<== change sheet as required.


Sub Start()
    Call CreateClipWindow
End Sub

Sub Finish()
    Call CleanUp
End Sub


'_______________________________________ PRIVATE ROUTINES __________________________________________________

Private Sub CreateClipWindow()
    #If Win64 Then
      Dim lHiddenWnd As LongLong
    #Else
      Dim lHiddenWnd As Long
    #End If
    If GetProp(Application.hwnd, "HiddenWnd") = 0 Then
        lHiddenWnd = CreateWindowEx(0, "Static", vbNullString, 0, 0, 0, 0, 0, 0, 0, 0, 0)
        Call SetProp(Application.hwnd, "HiddenWnd", lHiddenWnd)
        Call AddClipboardFormatListener(lHiddenWnd)
        Call SubClassClipBoardWatcherWindow(lHiddenWnd)
    End If
End Sub

Private Sub CleanUp()
    Call RemoveClipboardFormatListener(GetProp(Application.hwnd, "HiddenWnd"))
    Call SubClassClipBoardWatcherWindow(GetProp(Application.hwnd, "HiddenWnd"), False)
    Call DestroyWindow(GetProp(Application.hwnd, "HiddenWnd"))
    Call RemoveProp(Application.hwnd, "HiddenWnd")
End Sub
 
#If Win64 Then
    Private Sub SubClassClipBoardWatcherWindow(ByVal hwnd As LongLong, Optional ByVal bSubclass As Boolean = True)
#Else
    Private Sub SubClassClipBoardWatcherWindow(ByVal hwnd As Long, Optional ByVal bSubclass As Boolean = True)
#End If
    Const GWL_WNDPROC = (-4)
    If bSubclass Then
        If GetProp(Application.hwnd, "PrevProcAddr") = 0 Then
            Call SetProp(Application.hwnd, "PrevProcAddr", _
                SetWindowLong(hwnd, GWL_WNDPROC, AddressOf ClipBoardWindowCallback))
        End If
    Else
        If GetProp(Application.hwnd, "PrevProcAddr") Then
            Call SetWindowLong(hwnd, GWL_WNDPROC, GetProp(Application.hwnd, "PrevProcAddr"))
            Call RemoveProp(Application.hwnd, "PrevProcAddr")
        End If
    End If
End Sub

#If Win64 Then
    Private Function ClipBoardWindowCallback( _
        ByVal hwnd As LongLong, _
        ByVal uMsg As Long, _
        ByVal wParam As LongLong, _
        ByVal lParam As LongLong _
    ) As LongLong
#Else
    Private Function ClipBoardWindowCallback( _
        ByVal hwnd As Long, _
        ByVal uMsg As Long, _
        ByVal wParam As Long, _
        ByVal lParam As Long _
    ) As Long
#End If

    Const WM_CLIPBOARDUPDATE = &H31D
    Static lPrevSerial As Long
    Dim sCurClipText As String
 
    Call SubClassClipBoardWatcherWindow(hwnd, False)
    If uMsg = WM_CLIPBOARDUPDATE Then
        If lPrevSerial <> GetClipboardSequenceNumber Then
            sCurClipText = GetClipText
            If Len(sCurClipText) Then
                If SheetExistes(TARGET_SHEET) Then
                    Call AddClipContentToSheet(Worksheets(TARGET_SHEET), sCurClipText)
                End If
            End If
            lPrevSerial = GetClipboardSequenceNumber
        End If
    End If
    Call SubClassClipBoardWatcherWindow(hwnd, True)
    ClipBoardWindowCallback = CallWindowProc(GetProp(Application.hwnd, "PrevProcAddr"), hwnd, uMsg, wParam, lParam)
End Function

Private Sub AddClipContentToSheet(ByVal Sh As Worksheet, ByVal sClipContent As String)
    With Sheet1.Cells(Rows.Count, 1).End(xlUp)
        .Offset(1) = .Offset(1).Row - 5
        .Offset(1, 1) = sClipContent
        .Offset(1, 2) = Format(Now, "hh:mm:ss")
    End With
End Sub

Private Function GetClipTextAPI() As String
    'Doesn't work if data is copied from within excel.
    'Func not used here ...kept for the record only.
    Const CF_UNICODETEXT = &HD&
    #If Win64 Then
        Dim lStrPtr As LongLong
    #Else
        Dim lStrPtr As Long
    #End If
 
    On Error GoTo errHandler
    Call OpenClipboard(0&)
    If IsClipboardFormatAvailable(CF_UNICODETEXT) Then
        lStrPtr = GetClipboardData(CF_UNICODETEXT)
        If lStrPtr Then
            GetClipTextAPI = String$(lstrlenW(lStrPtr), vbNullChar)
            lstrcpyW StrPtr(GetClipTextAPI), GlobalLock(lStrPtr)
            Call GlobalUnlock(lStrPtr)
        End If
    End If
errHandler:
    Call CloseClipboard
End Function

Private Function GetClipText() As String
    On Error Resume Next
    With CreateObject("htmlfile")
        With .ParentWindow.ClipboardData
            GetClipText = .GetData("Text")
        End With
    End With
End Function

Private Function SheetExistes(ByVal ShName As String) As Boolean
    On Error Resume Next
    SheetExistes = Not IsError(ThisWorkbook.Worksheets(ShName))
End Function

Private Sub Auto_Close()
    Call CleanUp
End Sub
Click to expand...
This is awesome. I love it. Thank you.
 
Upvote 0
You must log in or register to reply here.

Similar threads

K
  • Question Question
copy Excel compatible URL page content to Clipboard
Replies
3
Views
79
Dan_W
D
W
  • Question Question
VBA to Copy Excel cells (one at a time) text to Windows Clipboard so that the text can be Pasted into another application using Windows+V
Replies
3
Views
284
WFCompany
W
J
  • Question Question
Copy string to windows clipboard VBA
Replies
2
Views
691
Artik
Artik
B
  • Question Question
Paste All from Excel clipboard has inconsistent errors
Replies
1
Views
553
Bumbles
B
B
  • Question Question
Fill up non contiguous cells from contiguous cells/clipboard/range
Replies
7
Views
166
Bawltea
B

Forum statistics

Threads
1,224,737
Messages
6,180,657
Members
452,992
Latest member
TokugawaIesuma

Share this page

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top