Use collection to store class objects

[KDEBR]

Hello
I want to use a collection that contains different car objects.
I'm familiar to do this in Java but I don't find the solution in VBA.

I want to create a class car where I can create my car object with contains the following parameters
make
model
year
therefore I have to make a class module?

I want to a list that I have in excel with the actual makes and models.

How can I store these objects in a collection?
I declare the collection in the module section?

Thanks for you feedback!

 

[Marcelo Branco]

Take a look at
https://excelmacromastery.com/vba-class-modules/

Hope this helps

M.

 

[KDEBR]

Thanks for the feedback but I'm still facing diffficulties.
I've tried to do this in C# and there I would use the code below.

I have the main class to run the program. I also have a vehicle class to make vehicle objects and those vehicle objects I'll keep the in a collection list class overview.
How could I do this in Excel?

class Program
{
static void Main(string[] args)
{
Overview lijst = new Overview();

lijst.add(new Vehicle("Audi","A3"));
lijst.add(new Vehicle("BMW", "1"));
Console.ReadLine();
}
}


class Vehicle
{
private string merk;
private string model;



public Vehicle(string merk, string model)
{
this.merk = merk;
this.model = model;


}
public string getMerk()
{
return merk;
}


public string getModel()
{
return model;
}
}


class Overview
{
private List<Vehicle> lijst;


public Overview()
{
lijst = new List<Vehicle>();
}


public void add(Vehicle vehicle)
{
lijst.Add(vehicle);
}
}

 

[Kyle123]

The link above has examples of exactly what you are trying to do. Where are you stuck? - Post your VBA code, not your C#

 

[Marcelo Branco]

I do not have much experience using Classes, but this worked for me

Class Module
Vehicle

Option Explicit

Private strMaker As String
Private strModel As String
Private lngYear As Long

Public Property Get Maker() As String
    Maker = strMaker
End Property

Public Property Let Maker(ByVal sMaker As String)
    strMaker = sMaker
End Property

Public Property Get Model() As String
    Model = strModel
End Property

Public Property Let Model(ByVal sModel As String)
    strModel = sModel
End Property

Public Property Get Year() As String
    Year = lngYear
End Property

Public Property Let Year(ByVal lYear As String)
    lngYear = lYear
End Property

Code in a standard module

Sub Main()
    Dim oVeh As Vehicle, myCol As Collection
    Dim V As Vehicle
        
    Set myCol = New Collection
    
    Set oVeh = New Vehicle
    oVeh.Maker = "Audi"
    oVeh.Model = "A3"
    oVeh.Year = 2017
    myCol.Add oVeh
    
    Set oVeh = New Vehicle
    oVeh.Maker = "BMW"
    oVeh.Model = "1"
    oVeh.Year = 2018
    myCol.Add oVeh
    
    For Each V In myCol
        Debug.Print "Maker= " & V.Maker
        Debug.Print "Model= " & V.Model
        Debug.Print "Year= " & V.Year
    Next V
End Sub

Hope this helps

M.