Updating Cell Value with changing other cell value of same row

[nareshjoshy]

Hello sir,

I'm using code:

Private Sub Worksheet_Change(ByVal Target As Range)



If Not Intersect(Target, Range("R2:R21")) Is Nothing Then
Cells(Target.Row, "S") = BS2AD(Cells(Target.Row, "R"))
Exit Sub
ElseIf Not Intersect(Target, Range("S2:S21")) Is Nothing Then
Cells(Target.Row, "R") = AD2BS(Cells(Target.Row, "S"))
Exit Sub
End If


If Not Intersect(Target, Range("T2:T21")) Is Nothing Then
Cells(Target.Row, "U") = BS2AD(Cells(Target.Row, "T"))
Exit Sub
ElseIf Not Intersect(Target, Range("U2:U21")) Is Nothing Then
Cells(Target.Row, "T") = AD2BS(Cells(Target.Row, "U"))
Exit Sub
End If


If Not Intersect(Target, Range("V2:V21")) Is Nothing Then
Cells(Target.Row, "W") = BS2AD(Cells(Target.Row, "V"))
Exit Sub
ElseIf Not Intersect(Target, Range("W2:W21")) Is Nothing Then
Cells(Target.Row, "V") = AD2BS(Cells(Target.Row, "W"))
Exit Sub
End If


End Sub

but it shows runtime error 8.

Please help me to sove this problem.

Thanks in advance.

 

[My Aswer Is This]

I always like it when users tell me what their trying to do. Showing me a script you have that does not work with no explanation of what your attempting to do is not something I cannot do.

Please explain in detail what your attempting to do.

 

[Fluff]

What are BS2AD and AD2BS?

 

[nareshjoshy]

Please explain in detail what your attempting to do.

I want to update cell value of same row if I update other cell value.

for i.e. If id update cell(R2) then cell(S2) should be updated only. similerly if i update cell(S2) then cell(R2) should be updated only and vice versa.

But my above code update Cell(S2) as wll as cell(R2) even after updating cell(R2) or cell(S2) and then popup error msg.

What are BS2AD and AD2BS?

BS2AD and AD2BS is my function to change BS date to AD date and AD date to BS date.

 

[Fluff]

Try

Private Sub Worksheet_Change(ByVal Target As Range)

On Error GoTo Xit
Application.EnableEvents = False
If Not Intersect(Target, Range("R2:R21")) Is Nothing Then
   Cells(Target.Row, "S") = BS2AD(Cells(Target.Row, "R"))
   Exit Sub
ElseIf Not Intersect(Target, Range("S2:S21")) Is Nothing Then
   Cells(Target.Row, "R") = AD2BS(Cells(Target.Row, "S"))
   Exit Sub
ElseIf Not Intersect(Target, Range("T2:T21")) Is Nothing Then
   Cells(Target.Row, "U") = BS2AD(Cells(Target.Row, "T"))
   Exit Sub
ElseIf Not Intersect(Target, Range("U2:U21")) Is Nothing Then
   Cells(Target.Row, "T") = AD2BS(Cells(Target.Row, "U"))
   Exit Sub
ElseIf Not Intersect(Target, Range("V2:V21")) Is Nothing Then
   Cells(Target.Row, "W") = BS2AD(Cells(Target.Row, "V"))
   Exit Sub
ElseIf Not Intersect(Target, Range("W2:W21")) Is Nothing Then
   Cells(Target.Row, "V") = AD2BS(Cells(Target.Row, "W"))
   Exit Sub
End If
Xit:
Application.EnableEvents = True

End Sub

 

[nareshjoshy]

Hello Fluff,

Thank for you code.

Above code works in first update only. after second update there is no effect on cell value change.

 

[Fluff]

Run this

Sub Chk()
Application.EnableEvents = True
End Sub

and then try

Private Sub Worksheet_Change(ByVal Target As Range)

On Error GoTo Xit
Application.EnableEvents = False
If Not Intersect(Target, Range("R2:R21")) Is Nothing Then
   Cells(Target.Row, "S") = BS2AD(Cells(Target.Row, "R"))
ElseIf Not Intersect(Target, Range("S2:S21")) Is Nothing Then
   Cells(Target.Row, "R") = AD2BS(Cells(Target.Row, "S"))
ElseIf Not Intersect(Target, Range("T2:T21")) Is Nothing Then
   Cells(Target.Row, "U") = BS2AD(Cells(Target.Row, "T"))
ElseIf Not Intersect(Target, Range("U2:U21")) Is Nothing Then
   Cells(Target.Row, "T") = AD2BS(Cells(Target.Row, "U"))
ElseIf Not Intersect(Target, Range("V2:V21")) Is Nothing Then
   Cells(Target.Row, "W") = BS2AD(Cells(Target.Row, "V"))
ElseIf Not Intersect(Target, Range("W2:W21")) Is Nothing Then
   Cells(Target.Row, "V") = AD2BS(Cells(Target.Row, "W"))
End If
Xit:
If Err.Number <> 0 Then
   MsgBox "Error " & Err.Number & " " & Err.Description & " occured"
End If
Application.EnableEvents = True

End Sub