Update the code to just change the format of a few columns instead of the whole sheet

[An Quala]

Hello, what if I just to change the formats of 2 columns instead of updating for the whole sheet?

Columns D and F in "Sponsored Products Campaigns" and "Sponsored Brands Campaigns"

Columns D and E in "Sponsored Display Campaigns"

Only these columns not the whole sheets please,

Please help?

Dim c As Range, va, x
     For Each x In Split("Sponsored Products Campaigns|Sponsored Brands Campaigns|Sponsored Display Campaigns", "|")
        Set c = Worksheets(x).UsedRange
        If c.Address <> "$A$1" Then
        va = c.Value
        Worksheets(x).Cells.NumberFormat = "General"
        c = va
        End If
    Next

 

[DanteAmor]

Try this:

Sub formatcells()
  Dim c As Range, va, x
  For Each x In Split("Sponsored Products Campaigns|Sponsored Brands Campaigns|Sponsored Display Campaigns", "|")
    Set c = Worksheets(x).UsedRange
    If c.Address <> "$A$1" Then
      va = c.Value
      Select Case x
        Case "Sponsored Products Campaigns", "Sponsored Brands Campaigns"
          Worksheets(x).Range("D:D, F:F").NumberFormat = "General"
        Case "Sponsored Display Campaigns"
          Worksheets(x).Range("D:E").NumberFormat = "General"
      End Select
      c = va
    End If
  Next
End Sub

Or like this to avoid typing the sheet names again:

Sub formatcells2()
  Dim c As Range, va, arr
  Dim i As Long
  arr = Array("Sponsored Products Campaigns", "Sponsored Brands Campaigns", "Sponsored Display Campaigns")
  For i = 0 To UBound(arr)
    Set c = Worksheets(arr(i)).UsedRange
    If c.Address <> "$A$1" Then
      va = c.Value
      Select Case i
        Case 0, 1
          Worksheets(arr(i)).Range("D:D, F:F").NumberFormat = "General"
        Case 2
          Worksheets(arr(i)).Range("D:E").NumberFormat = "General"
      End Select
      c = va
    End If
  Next
End Sub

 

[An Quala]

Works great, thank you!

 

[DanteAmor]

Im glad to help you. Thanks for the feedback.