Update image file name based on textbox content

[kelly mort]

When I enter the textbox, I want to store its content to a variable "MyEnter". Then when I change the content I store the changed content to " MyChange".

Then inside a folder , "MyPics", located at the location of the workbook, if there is an image file called same as the content of the " MyEnter" variable, then I will compare "MyEnter" with "MyChange". If they are different, then I rename the image with " MyChange" , by the click of a button on a userform. The textbox too is on the userform as well.

I am stacked and I need some support with the code

Thanks in advance

 

[Yongle]

Hi

The code adds the extension ".jpg" when textbox value is saved to variable
- is that the correct extension ?

Declare these public variables at top of STANDARD module (above all procedures)

Public MyEnter As String
Public MyChange As String

USERFORM code

Private Sub CommandButton1_Click()
    Dim fPath As String
    fPath = ThisWorkbook.Path & "\MyPics\"
    On Error Resume Next
    Name fPath & MyEnter As fPath & MyChange
    If Err.Number > 0 Then MsgBox Err.Description
End Sub

Private Sub TextBox1_Change()
    MyChange = TextBox1.Text & ".jpg"
End Sub

Private Sub TextBox1_Enter()
    MyEnter = TextBox1.Text & ".jpg"
End Sub

 

[kelly mort]

Hi

The code adds the extension ".jpg" when textbox value is saved to variable
- is that the correct extension ?

Declare these public variables at top of STANDARD module (above all procedures)

Public MyEnter As String
Public MyChange As String

USERFORM code

Private Sub CommandButton1_Click()
    Dim fPath As String
    fPath = ThisWorkbook.Path & "\MyPics\"
    On Error Resume Next
    Name fPath & MyEnter As fPath & MyChange
    If Err.Number > 0 Then MsgBox Err.Description
End Sub

Private Sub TextBox1_Change()
    MyChange = TextBox1.Text & ".jpg"
End Sub

Private Sub TextBox1_Enter()
    MyEnter = TextBox1.Text & ".jpg"
End Sub

Yes extension is correct.

And the code works very brilliantly!!!

For now I don't think I will have a problem with the file extension. But for future sake is there a way to use the file extension from the file itself instead of the hard coded .jpg?

Thanks for the code

 

[Yongle]

ok - will post code tomorrow when back at PC

 

[Yongle]

Test this with different extensions to see if it achieves what you want

in STANDARD module

Public MyEnter As String
Public MyChange As String

in USERFORM module

Private Sub CommandButton1_Click()
    Dim fPath As String, sFile As String, Ext As String
    fPath = ThisWorkbook.Path & "\MyPics\"
    sFile = Dir(fPath & MyEnter & ".*")
    Do While Len(sFile) > 0
        Ext = Right(sFile, Len(sFile) + 1 - InStrRev(sFile, "."))
        Name fPath & MyEnter & Ext As fPath & MyChange & Ext
        sFile = Dir
    Loop
End Sub

Private Sub TextBox1_Change()
    MyChange = TextBox1.Text
End Sub

Private Sub TextBox1_Enter()
    MyEnter = TextBox1.Text
End Sub

 

[kelly mort]

Great!!!!

I have tested it for five different extensios and it worked so great and faster...

I am very grateful for your time thanks so much.