unique with sort

[orsm6]

Hi all - trying to return a unique list that is sorted high to low, but struggling.

using this formula: =SORT(UNIQUE(FILTER(Table134[score],(Table134[DIV]=2)*(Table134[WEEK]='WEEKLY SUMMARY'!X3))),,1)
or =SORT(UNIQUE(FILTER(Table134[score],(Table134[DIV]=2)*(Table134[WEEK]='WEEKLY SUMMARY'!X3))),,-1)

isn't working.....

it will result in as example:
10-5
13-2
9-6

where as i need to show
13-2
10-5
9-6

what am i doing wrong?
also to be noted is that the number list that the formula points at is a concatenated list.

TIA

 

[Georgiboy]

Try it as below:
=let(u,UNIQUE(FILTER(Table134[score],(Table134[DIV]=2)*(Table134[WEEK]='WEEKLY SUMMARY'!X3))),sortby(u,--TEXTBEFORE(u,"-"),-1))

Book1
	A	B
2	10-5	13-2
3	13-2	10-5
4	9-6	9-6
Sheet2

Cell Formulas
Range	Formula
B2:B4	B2	=SORTBY(A2:A4,--TEXTBEFORE(A2:A4,"-"),-1)
Dynamic array formulas.

 

[orsm6]

Try it as below:
=let(u,UNIQUE(FILTER(Table134[score],(Table134[DIV]=2)*(Table134[WEEK]='WEEKLY SUMMARY'!X3))),sortby(u,--TEXTBEFORE(u,"-"),-1))

Book1
	A	B
2	10-5	13-2
3	13-2	10-5
4	9-6	9-6
Sheet2

Cell Formulas
Range	Formula
B2:B4	B2	=SORTBY(A2:A4,--TEXTBEFORE(A2:A4,"-"),-1)
Dynamic array formulas.

thank you for your help, this works great for having the numbers sorted in the right order, but I didn't account for the word "bye" which is now at the top of the list.... but that's ok, i might be able to do something

 

[Fluff]

To handle text you could use

Fluff.xlsm
	A	B
1
2	10-5	13-2
3	13-2	10-5
4	9-6	9-6
5	bye	bye
Master

Cell Formulas
Range	Formula
B2:B5	B2	=SORTBY(A2:A5,IFERROR(--TEXTBEFORE(A2:A5,"-"),0),-1)
Dynamic array formulas.

 

[Peter_SSs]

Could also use TEXTBEFORE's final optional argument.

23 07 18.xlsm
	A	B
1
2	10-5	13-2
3	13-2	10-5
4	bye	9-6
5	9-6	bye
Sortby

Cell Formulas
Range	Formula
B2:B5	B2	=SORTBY(A2:A5,--TEXTBEFORE(A2:A5,"-",,,,0),-1)
Dynamic array formulas.

 

[orsm6]

To handle text you could use

Fluff.xlsm
	A	B
1
2	10-5	13-2
3	13-2	10-5
4	9-6	9-6
5	bye	bye
Master

Cell Formulas
Range	Formula
B2:B5	B2	=SORTBY(A2:A5,IFERROR(--TEXTBEFORE(A2:A5,"-"),0),-1)
Dynamic array formulas.

appreciate your help, thank you i like solutions

 

[orsm6]

Could also use TEXTBEFORE's final optional argument.

23 07 18.xlsm
	A	B
1
2	10-5	13-2
3	13-2	10-5
4	bye	9-6
5	9-6	bye
Sortby

Cell Formulas
Range	Formula
B2:B5	B2	=SORTBY(A2:A5,--TEXTBEFORE(A2:A5,"-",,,,0),-1)
Dynamic array formulas.

appreciate your help, thank you i like solutions

 

[Peter_SSs]

You're welcome. Glad we could help. Thanks for the follow-up.